如何在windows中为Perl6创建弹出窗口？

Question

我正在使用Windows 7和10rakudo-star-2019.03-x86_64（JIT）。我想知道如何在Perl6中创建一个弹出窗口来向用户提供信息？类似Linux的发送通知或Windows Pro msg（没有网络）

非常感谢，-T

Answer 1

我把你的例子变成了一个模块。非常感谢。

# unit module WinMsg;
# WinMsg.pm6

#`{
Reference: https://stackoverflow.com/questions/59105696/how-can-i-create-pop-up-windows-for-perl6-in-windows
}

use NativeCall;

sub WinMsg( Str $TitleStr, Str $MessageStr ) is export( :WinMsg ) {

   constant WCHAR              = uint16;
   constant INT                = int32;
   constant UINT               = uint32;
   constant HANDLE             = Pointer[void];
   constant LPWCTSTR           = CArray[WCHAR];
   constant MB_ICONEXCLAMATION = 0x00000030;

   # Note: the following two subs have to be embedded

   sub MessageBoxW( HANDLE, LPWCTSTR, LPWCTSTR, UINT ) is native('user32') returns INT { * };

   sub to-c-str( Str $str ) returns CArray[WCHAR]  {
      my @str := CArray[WCHAR].new;
      for ( $str.comb ).kv -> $i, $char { @str[$i] = $char.ord; }
      @str[ $str.chars ] = 0;
      @str;
   }


    # MessageBoxW( my $handle, to-c-str("๘❤ Raku is awesome ❤๖"), to-c-str("Hellö Wαrld"), MB_ICONEXCLAMATION );

    MessageBoxW( my $handle, to-c-str( $MessageStr ), to-c-str( $TitleStr ), MB_ICONEXCLAMATION );
}

试车线：

>perl6 -e "use lib '.'; use WinMsg :WinMsg; WinMsg( 'Super Duper Title', 'What? You were expecting something witty?' );"

Answer 2

一个简单的Messagebox足够好吗？然后

use NativeCall;

constant WCHAR              = uint16;
constant INT                = int32;
constant UINT               = uint32;
constant HANDLE             = Pointer[void];
constant LPWCTSTR           = CArray[WCHAR];
constant MB_ICONEXCLAMATION = 0x00000030;

sub MessageBoxW( HANDLE, LPWCTSTR, LPWCTSTR, UINT ) is native('user32') returns INT { * };

MessageBoxW( my $handle, to-c-str("๘❤ Raku is awesome ❤๖"), to-c-str("Hellö Wαrld"), MB_ICONEXCLAMATION );

sub to-c-str( Str $str ) returns CArray[WCHAR]
{
    my @str := CArray[WCHAR].new;
    for ( $str.comb ).kv -> $i, $char { @str[$i] = $char.ord; }
    @str[ $str.chars ] = 0;
    @str;
}

对于任何更复杂的东西，我认为GUI目前唯一可用的选项是Tk绑定。