如何为类创建工厂？

Question

我有以下代码：

class kg is Dimension {
    method new() {
        return self.bless(
                :type('mass'),
                :abbr('kg'),
                :multiplier(Multiplier.new(
                        numerator =>   1.0,
                        denominator => Quantity.new(1000.0, 'g')))),
    }
}

class mg is Dimension {
    method new() {
        return self.bless(
                :type('mass'),
                :abbr('mg'),
                :multiplier(Multiplier.new(
                        numerator =>   1000.0,
                        denominator => Quantity.new(1.0, 'g')))),
    }
}

我将添加更多类似的类。与其单独拼出所有这些类，我想学习如何创建一个可以从简单的数据结构创建这些类的工厂。

我该怎么做？我阅读了Metaobject协议文档，但根据文档页面顶部和中间的示例，我不知道如何动态地为我的类指定不同的名称。

我试过：

constant A := Metamodel::ClassHOW.new_type( name => 'A' );
A.^add_method('x', my method x(A:) { say 42 });
A.^add_method('set', my method set(A: Mu \a) { A.^set_name(a) });
A.^compose;

my $bar = A;
$bar.set('Foo');
say $bar.^name;  # 
A.x;             # works
Foo.x;           # error

但最后一行只是抛出了一个错误：

Undeclared name:
    Foo used at line 13

Answer 1

您应该意识到的第一件事是，任何类型的元编程通常都需要在编译时完成，也就是在BEGIN块中。

其次：目前，Raku具有一些用于创建代码的元编程功能，但并非所有功能都需要使其尽可能轻松。RakuAST的工作将改变这一点，因为它基本上使Raku本身是从公共元编程API构建的（而不是你可以争辩的是，当前的引导版本使用了大量NQP）。

我已将您的代码重写为以下内容：

sub frobnicate(Str:D $name) {
    my \A := Metamodel::ClassHOW.new_type(:$name);
    A.^add_method('x', my method x() { say 42 });
    A.^compose;
    OUR::{$name} := A;
}

BEGIN frobnicate("Foo");
say Foo.^name;  # Foo
Foo.x;          # 42

因此，这引入了一个名为frobnite的子类，它创建了一个具有给定名称的新类型。向其中添加方法x，并组成新类型。然后确保它在当前编译单元中被称为我们的。

然后，在编译时通过在BEGIN前面加前缀来调用frobnite子脚本。这一点很重要，因为在编译下一行时，将无法知道其他的Foo，因此可能会出现错误。

目前有一个小问题：

dd Foo.^find_method("x").signature;  # :(Mu: *%_)

未设置发票约束。我还没有找到一种方法（在RakuAST之前）使用元编程接口来设置它。但我认为这不会成为你举的例子的问题。如果这确实成为一个问题，那么当我们到达那里时，让我们穿过那座桥。