xsl命名空间从根复制到子节点，复制命名空间="no"不工作（xslt 3.0版本）

Question

我正在尝试使用源代码xml的脚本，其结果可在下面的小提琴工具链接中获得

https://xsltfiddle.liberty-development.net/jxN9PRK/4

源XML:

<root xmlns="http://www.oracle.com/retail/integration/rib/RibMessages" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://mspdv170.us.oracle.com:7779/rib-func-artifact/integration/xsd/RibMessages.xsd">
   <parent>test</parent>
   <parentdtl>
   <child xmlns="http://test.com">
       <element1>1</element1>
   </child>   
   </parentdtl>
   <outer>T</outer>
</root> 

使用的XSL脚本：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xsi:schemaLocation="http://mspdv170.us.oracle.com:7779/rib-func-artifact/integration/xsd/RibMessages.xsd"
    exclude-result-prefixes="#all"
    version="3.0">
  <xsl:template match="*">
        <xsl:variable name="copy-sans-namespaces" as="element()">
            <xsl:copy-of select="." copy-namespaces="no"/>
        </xsl:variable>
        <xsl:variable name="ser-params" as="element()">
            <output:serialization-parameters xmlns:output="http://www.w3.org/2010/xslt-xquery-serialization">
                <output:omit-xml-declaration value="yes" />
            </output:serialization-parameters>
        </xsl:variable>
        <xsl:value-of select="serialize($copy-sans-namespaces, $ser-params)" />
    </xsl:template>
   <xsl:template match="*:root|*:parent|*:parentdtl|*:outer">
        <xsl:copy>
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template> 
</xsl:stylesheet>

预期产出：

<?xml version="1.0" encoding="UTF-8"?><root xmlns="http://www.oracle.com/retail/integration/rib/RibMessages" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:schemaLocation="http://mspdv170.us.oracle.com:7779/rib-func-artifact/integration/xsd/RibMessages.xsd">
   <parent>test</parent>
   <parentdtl>
   &lt;child xmlns="http://test.com"&gt;
       &lt;element1&gt;1&lt;/element1&gt;
   &lt;/child&gt;   
   </parentdtl>
   <outer>T</outer>
</root>

相反，我收到了下面的结果

<?xml version="1.0" encoding="UTF-8"?><root xmlns="http://www.oracle.com/retail/integration/rib/RibMessages" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
   <parent>test</parent>
   <parentdtl>
   &lt;child xmlns="http://test.com" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"&gt;
       &lt;element1&gt;1&lt;/element1&gt;
   &lt;/child&gt;   
   </parentdtl>
   <outer>T</outer>
</root>

XSL脚本面临两个问题，

>

XSL在转义时从根目录到子目录包含一个名称空间。xmlns:xsi=”http://www.w3.org/2001/XMLSchema-instance，但在转义

根目录中的名称空间并非全部复制到结果XML中。xsi:schemaLocation=”http://mspdv170.us.oracle.com:7779/rib-父级

请分享任何提示，因为我对XSLT非常陌生。XSL版本是3.0，在我正在做的项目中使用SAXON 9.6引擎。




Answer 1

Saxon 9.6的行为似乎是Saxon 10.2中仍然存在的一个bug，我在https://saxonica.plan.io/boards/3/topics/8011这导致了bug问题https://saxonica.plan.io/issues/4793.

作为一种解决方法，我想您需要通过节点推动元素，使用xsl:element进行复制，避免名称空间复制：

  <xsl:template match="*" mode="strip-in-scope-namespaces">
      <xsl:element name="{name()}" namespace="{namespace-uri()}">
          <xsl:copy-of select="@*"/>
          <xsl:apply-templates mode="#current"/>
      </xsl:element>
  </xsl:template>

  <xsl:template match="*">
        <xsl:variable name="copy-sans-namespaces" as="element()">
            <xsl:apply-templates select="." mode="strip-in-scope-namespaces"/>
        </xsl:variable>
      
        <xsl:variable name="ser-params" as="element()">
            <output:serialization-parameters xmlns:output="http://www.w3.org/2010/xslt-xquery-serialization">
                <output:omit-xml-declaration value="yes" />
            </output:serialization-parameters>
        </xsl:variable>

        <xsl:value-of select="serialize($copy-sans-namespaces, $ser-params)" />
    </xsl:template>

https://xsltfiddle.liberty-development.net/jxN9PRK/5

至于xsi:schemaLocationmissing，这是一个您忘记复制的属性；使用

   <xsl:template match="*:root|*:parent|*:parentdtl|*:outer">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>

https://xsltfiddle.liberty-development.net/jxN9PRK/6