用VBScript的FSO对象 /saveicacls读取结果失败

Question

我需要保存运行ICACLS命令的结果，更改它们，并将更改后的权限恢复回来。我使用vbcript来做到这一点。问题是，从保存的数据中读取行或整个数据会给我一个字符和一堆空格。但是如果我尝试读取结果数据的内容，由ICACLS上传，逐个字符，并动态打印，它会显示正确的内容。

Const ForReading=1 'I/O modes
dim FolderToSetPermissions,ShellObj,FSO,EffectivePermissionsFile,CurrentLine,ParentFolderName,ParentFolderObj
FolderToSetPermissions="c:\test"
Set FSO = CreateObject("Scripting.FileSystemObject")
ParentFolderName=FSO.GetParentFolderName(wscript.ScriptFullName)
Set ParentFolderObj =fso.GetFolder(ParentFolderName)    
Set ShellObj = WScript.CreateObject("WScript.Shell")
ShellObj.run "icacls.exe """&FolderToSetPermissions&"""\* /save " & ParentFolderObj.path & "\EffectivePermissions.txt /t", 0, True
set EffectivePermissionsFile =FSO.OpenTextFile(ParentFolderObj.path & "\EffectivePermissions.txt",ForReading,False)
Do Until EffectivePermissionsFile.AtEndOfStream
'CurrentLine=EffectivePermissionsFile.Read(1) ' works fine if prints right after 
 'reading from file. Concatenating all the chars in file causes the same result as 
 'reading the file by lines or with .ReadAll function of FSO
 CurrentLine= EffectivePermissionsFile.ReadLine
 WScript.Echo CurrentLine
Loop
EffectivePermissionsFile.Close

我怀疑，问题出在ICACLS本身：它不写一个真正的文本文件。我找到了另一个遇到这种情况的人（https://windowssecrets.com/forums/showthread.php/150866-Win7-ICACLS-redirected-output-and-NOTEPAD-don-t-play-well-together）。

P. S： CACLS写入正确的文本文件，读取时没有问题。但不幸的是，它不能在整个文件夹中进行递归。

Answer 1

读了几百页，我终于找到了解决办法！此函数转换由icacls创建的文本

Sub UTFConvert(filename)
  Set fso = CreateObject("Scripting.FileSystemObject")
  txt = fso.OpenTextFile(filename, 1, False, -1).ReadAll

  Set stream = CreateObject("ADODB.Stream")
  stream.Open
  stream.Type     = 2 'text
  stream.Position = 0
  stream.Charset  = "utf-8"
  stream.WriteText txt
  stream.SaveToFile filename, 2
  stream.Close
End Sub

随后，生成的文本将使用VBScript变得可读。

从这里得到答案： UCS-2小端到UTF-8转换会留下带有许多不需要的字符的文件