SoapUI Groovy Script，log.info有关运行的测试步骤的详细信息。

Question

我在SoapUI中有一个Groovy脚本，它可以为每个测试步骤记录该步骤是通过了还是失败了。我还希望Groovy脚本记录出错的断言消息。

import com.eviware.soapui.model.testsuite.Assertable.AssertionStatus

def TestCase = testRunner.getTestCase()
def StepList = TestCase.getTestStepList()
StepList.each{
    // check that testStep has assertionStatus 
    // (for example groovy testSteps hasn't this property since
    // there is no asserts on its)
    if(it.metaClass.hasProperty(it,'assertionStatus')){
        if(it.assertionStatus == AssertionStatus.FAILED){
            log.info "${it.name} FAILED"    

        }else if(it.assertionStatus == AssertionStatus.VALID){
            log.info "${it.name} Passed"
        }else if(it.assertionStatus == AssertionStatus.UNKNOWN){
            log.info "${it.name} UNKNOWN (PROBABLY NOT ALREADY EXECUTED)"
        }
    }
}

此时，我得到以下输出：

Thu Oct 20 11:31:06 BST 2016:INFO:TestStep_0051 Passed
Thu Oct 20 11:31:06 BST 2016:INFO:TestStep_0052 FAILED
Thu Oct 20 11:31:06 BST 2016:INFO:TestStep_0053 Passed

我希望失败的断言以更详细的方式显示它失败的原因的消息。如果失败的TestStep本身，我就会收到消息：

assert node.toString().matches("(0|175.238|0)\\d*")       |    |          |      |    |          false           |    132.497286826667           132.497286826667

此外，当我运行这个Groovy脚本时，会弹出一个名为“Information”的窗口，它的背景是黑色的，太宽了，我似乎找不到它的右侧。有人知道这是什么吗？

Answer 1

你可以试着修改一下你的代码，让我解释一下：

您可以使用getAssertionList（）访问testStep结果的最终AssertionState，而不是通过metaClass访问testStep的所有断言，以避免testSteps出现问题不包含断言，您可以使用metaClass检查此方法是否存在。

然后，对于此列表中的每个断言，您可以检查状态，对于失败的断言，您可以使用getError（）方法获取错误消息。

最后，为了避免由于默认情况下Groovy返回最后一个实例化对象（在脚本StepList中）并由SOAPUI提示而产生的提示消息，您可以添加一条return语句以不返回任何内容并避免提示效果。

import com.eviware.soapui.model.testsuite.Assertable.AssertionStatus

def TestCase = testRunner.getTestCase()
def StepList = TestCase.getTestStepList()
StepList.each{

    // check that this kind of testStep
    // can contain assertions (avoid errors with groovy testSteps)
    if(it.metaClass.respondsTo(it,"getAssertionList")){

         def assertions = it?.getAssertionList()

         assertions?.each{ assertion ->

            if(assertion?.getStatus() == AssertionStatus.FAILED){
              log.info "${it.name} FAILED"
               assertion?.getErrors()?.each{ error ->
                 log.info "Error message ${error.getMessage()}"
               }
            }else if(assertion?.getStatus() == AssertionStatus.VALID){
                log.info "${it.name} Passed"
            }else if(assertion?.getStatus() == AssertionStatus.UNKNOWN){
                log.info "${it.name} UNKNOWN (PROBABLY NOT ALREADY EXECUTED)"
            }
         }
     }
}
return