基于值的XSLT属性更改

Question

我是XSLT新手，希望能得到一些帮助。

我目前有一个XML，它包含以下格式的多个副本：

          <item:items>
            <item:item action="ingest" id="USAUS868509">
                <item:itemID>1157245</item:itemID>
                <item:spotType>commercial</item:spotType>
            </item:item>
           <item:items>

我的任务是替换id属性的值。我需要根据代码的数字部分改变这个值。如果值大于850000，格式应该改为USA868509。如果该值小于850000，则将id值更改为仅包括数字。XML中的其余值应保持完全相同。

我目前拥有以下xslt：

             <xsl:template match="@*|node()">
                <xsl:copy>
                    <xsl:apply-templates select="@*|node()"/>
                   </xsl:copy>
              </xsl:template>

             <xsl:template match="//items/item[@id]">  
                <xsl:choose>
                    <xsl:when test="substring(id,5) &gt;= 845986">
                        <xsl:attribute name="id">
                            <xsl:value-of select="substring(id,5)"/>
                        </xsl:attribute> 
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:attribute name="id">
                            <xsl:value-of select="id"/>
                        </xsl:attribute> 
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:template>  

我很难确定要更改的值，因为XSLT不执行变量循环。有没有办法更改XSLT以获得这种逻辑？

Answer 1

让我们有以下格式良好的输入示例：

XML

<items>
  <item action="ingest" id="USAUS849999">
    <itemID>1157245</itemID>
    <spotType>commercial</spotType>
  </item>
  <item action="ingest" id="USAUS850001">
    <itemID>1157246</itemID>
    <spotType>commercial</spotType>
  </item>
</items>

应用以下样式表：

XSLT1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="@id">
    <xsl:variable name="code" select="substring(., 6)" />
    <xsl:attribute name="id">
        <xsl:if test="$code >= 850000">USA</xsl:if>
        <xsl:value-of select="$code" />
    </xsl:attribute>
</xsl:template>

</xsl:stylesheet>

将产生以下结果：

<?xml version="1.0" encoding="UTF-8"?>
<items>
   <item action="ingest" id="849999">
      <itemID>1157245</itemID>
      <spotType>commercial</spotType>
   </item>
   <item action="ingest" id="USA850001">
      <itemID>1157246</itemID>
      <spotType>commercial</spotType>
   </item>
</items>