XSLT转换：根据其属性值平坦嵌套节点

Question

我想使用XSLT展平XML文件。示例（可以有任意数量的节点和边缘节点）：

输入：

<?xml version="1.0" encoding="utf-8"?>
<graphml xmlns="http://graphml.graphdrawing.org/xmlns">
  <graph>

    <node id="0">
      <data key="label">A</data>
      <data key="tag1">0</data>
      <data key="tag2">0</data>
    </node>

    <edge id="0" source="0" target="1">
      <data key="label">REFERENCED_TO</data>
    </edge>

  </graph>
</graphml>

期望输出：

<?xml version="1.0" encoding="utf-8"?>
<graphml xmlns="http://graphml.graphdrawing.org/xmlns">
  <graph>

    <node id="0" label="A">          
      <data key="tag1">0</data>
      <data key="tag2">0</data>
    </node>

    <edge id="0" source="1" target="0" label="REFERENCED_TO"/>

  </graph>
</graphml>

如何仅展平那些将键属性设置为“label”的数据标记？

Answer 1

hor257k的解决方案似乎包含@key='tag'的三个测试。这里有一个改进它的尝试：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:gml="http://graphml.graphdrawing.org/xmlns">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!-- convert label element to attribute -->
<xsl:template match="gml:data[@key='label']">
  <xsl:attribute name="label">
    <xsl:value-of select="."/>
  </xsl:attribute>
</xsl:template>

</xsl:stylesheet>

为了完整起见，这里是XSLT 3.0版本：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:gml="http://graphml.graphdrawing.org/xmlns">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:mode on-no-match="shallow-copy"/>

<!-- convert label element to attribute -->
<xsl:template match="gml:data[@key='label']">
  <xsl:attribute name="label" select="."/>
</xsl:template>

</xsl:stylesheet>

Answer 2

有一些空闲时间，我想出了以下XSLT（它是基于1.0的，非常冗长）

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
                xmlns:g="http://graphml.graphdrawing.org/xmlns"
                exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">
      <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="*[*/@key='label']">
      <xsl:element name="{local-name()}" namespace="{namespace-uri()}">
        <xsl:copy-of select="@*"/>
      <xsl:attribute name="label">
        <xsl:value-of select="*[@key='label']/text()" />
      </xsl:attribute>
      <xsl:apply-templates select="*[not(@key='label')]"/>
      </xsl:element>
    </xsl:template>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

希望这有帮助，

Answer 3

如何才能将那些键属性设置为“标签”的数据标签展平？

怎么样：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:gml="http://graphml.graphdrawing.org/xmlns">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!-- add label attribute -->
<xsl:template match="gml:node | gml:edge">
    <xsl:copy>
        <xsl:if test="gml:data[@key='label']">
            <xsl:attribute name="label"><xsl:value-of select="gml:data[@key='label']"/></xsl:attribute>
        </xsl:if>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!-- suppress label element -->
<xsl:template match="gml:data[@key='label']"/>

</xsl:stylesheet>