如何从Groovy代码解析Jenkinsfile

Question

例如，我有一个包含一些属性的Jenkinsfile

trace = false

userNotifications = [
    build_master :                 [name : 'name',
                                    email : 'email',
                                    slackid: 'slack id',
                                    slackchannel: 'slack channel']
]
env.aProperty = "aValue"
node('COMPILE')
{
...
}

我想在groovy代码中解析上面的Jenkinsfile，以便访问一些属性值。

当我像这样使用GroovyShell时

        Binding binding = new Binding()
        GroovyShell shell = new GroovyShell(binding)
        Object groovyDsl = shell.evaluate(clean)

我得到这个错误

groovy.lang.MissingMethodException: No signature of method: Script1.node() is applicable for argument types: (String, Script1$_run_closure1) values: [COMPILE, Script1$_run_closure1@7d804e7]

我可能能够通过一些Groovy元编程绕过特定错误，但是，我不确定这是否是正确的方向。我的问题是，在Groovy代码中解析Jenkinsfile的最佳方法是什么？这就是Groovy DSL，我希望它更简单。

Answer 1

DSL是特定于上下文的，不能在上下文之外运行。

你可以试试

• 管理Jenkins下的脚本控制台

Answer 2

以下是我最终如何做到我想要的：

import org.codehaus.groovy.control.CompilerConfiguration

class JenkinsfileParser {
    static void main(String[] args) {
        LinkedHashMap vars = JenkinsfileParser.parse('Jenkinsfile' as File)
        println vars.toString()
    }

    static LinkedHashMap parse(File jenkinsfile) {
        CompilerConfiguration config = new CompilerConfiguration()
        config.scriptBaseClass = JenkinsfileBaseClass.class.name
        Binding binding = new Binding()
        GroovyShell shell = new GroovyShell(this.class.classLoader, binding, config)
        String clean = jenkinsfile.text.replace('import hudson.model.*', '')
                .replace('import hudson.EnvVars', '')
        Script script = shell.parse(clean)
        script.run()
        return binding.variables
    }

    static abstract class JenkinsfileBaseClass extends Script {
        LinkedHashMap<String, Closure> nodeClosures = new LinkedHashMap<>()
        LinkedHashMap env = new LinkedHashMap()
        CurrentBuild currentBuild = new CurrentBuild()
        LinkedHashMap parallelClosures = new LinkedHashMap<>()

        void node(String name, Closure closure) {
            nodeClosures.put(name, closure)
        }

        void parallel(LinkedHashMap closures) {
            parallelClosures.putAll(closures)
        }

        class CurrentBuild {
            List<String> expectedResults = new ArrayList<>()

            boolean resultIsBetterOrEqualTo(String expected) {
                expectedResults << expected
                return true
            }
        }
    }
}

JenkinsfileBaseClass特定于我的Jenkinsfile，需要对不同的Jenkinsfile进行修改。

相关文件可在此处找到：https://groovy-lang.org/integrating.html

我试着使用实现组：“org”。詹金斯ci。main，名称：“jenkins core”，版本：“2.9”来自maven存储库的包http://repo.jenkins-ci.org/public/，然而，这里似乎没有任何对我的案例有用的东西。

如果有更好或更优雅的方法，请告诉我。