从属性文件加载属性并使其在整个作业/管道中可用-Jenkins声明性语法

Question

我的要求很简单，我只是想外部化一些“值”以使我的Jenkinsfile更可重用，为此我需要从Jenkinsfile旁边的文件中加载属性，并确保这些属性在管道中的任何地方都可用。我对groovy和Jenkins代码仍然是新手，但从未想过如此简单的事情会如此困难。我在脚本安全插件中启用了一些方法，但以下代码（以及我尝试过的几种变体）总是会导致错误或打印null或给我NPE。我尝试了多种组合，下面的代码只是其中之一。

properties = null

@NonCPS
def loadProperties() {
    checkout scm
    File propertiesFile = new File('${workspace}/pipeline.properties')
    propertiesFile.withInputStream {
            properties.load(propertiesFile)
    }
}

pipeline {
    agent none

    stages {

        stage ('prepare') {
            agent any

            steps {
                script {
                loadProperties()
                echo "${properties['repo']}"
                }
            }
        }
        stage('Build') {

            agent any

            steps {
                sh 'echo ${properties.repo}'
            }

        }
    }
}

Answer 1

使用“pipeline utility steps”插件，可以定义可用于所有阶段的常规变量。例如，让道具。txt格式：

version=1.0
fix=alfa

并将脚本和声明性Jenkins管道混合为：

def props
def VERSION
def FIX
def RELEASE

node {
   props = readProperties file:'props.txt'
   VERSION = props['version']
   FIX = props['fix']
   RELEASE = VERSION + "_" + FIX
}

pipeline {
   stages {
      stage('Build') {
         echo ${RELEASE}
      }
   }
}

Answer 2

感谢您的回答#1。这很有帮助，我使用了选项2。我遇到了一些问题，希望与大家分享我的解决方案：

1） 我在声明性管道的管道部分添加了一个“准备”阶段：

stage ('Prepare') {
   steps {
      script {
         properties = readProperties file: 'scripts/jenkins-pipelines/branch-specific.properties'
         echo "Running build ${JOB_NAME} # ${BUILD_NUMBER} on git repo ${properties.GitURL} branch ${properties.nextBranchName}"
       }
     }
   }
}

属性文件的格式为：

nextBranchName=next
stableBranchName=master
GitURL=[e-mail]:foo.git

请注意，属性上没有报价。

我在其他步骤、阶段和post中也使用了${properties.nextBranchName}属性。如回答1所述：需要安装“pipeline utility steps”插件

Answer 3

我想出了两种在Jenkins管道中实现属性外部化的方法。您可以根据主要差异选择您的选择。

1） 完全使用groovy代码。此代码段要求您在脚本安全插件附带的“过程中脚本审批”中启用多个方法签名，因此只有在适当考虑后才能执行此操作。

properties = null     

def loadProperties() {
    node {
        checkout scm
        properties = new Properties()
        File propertiesFile = new File("${workspace}/pipeline.properties")
        properties.load(propertiesFile.newDataInputStream())
        echo "Immediate one ${properties.repo}"
    }
}

pipeline {
    agent none

    stages {
        stage ('prepare') {
            agent any

            steps {
                script {
                    loadProperties()
                    echo "Later one ${properties.branch}"
                }
            }
        }
        stage('Build') {
            agent { label 'master'  }

            steps {
                // works fine. properties is available everywhere
                echo properties.branch
            }           
        }
    }
}

2） 使用管道实用程序步骤插件-管道插件套件默认包括这一点，它允许以更好的方式加载属性，而无需启用安全异常。我推荐这种方法。

properties = null

def loadProperties() {
    node {
        checkout scm
        properties = readProperties file: 'pipeline.properties'
        echo "Immediate one ${properties.repo}"
    }
}

pipeline {
    agent none

    stages {           
        stage ('prepare') {
            agent any

            steps {
                script {
                    loadProperties()
                    echo "Later one ${properties.ansible}"
                }
            }
        }
        stage('Build') {

            agent any

            steps {
                echo properties.branch
            }

        }
    }
}