使用ffmpeg合并多个视频和音频

Question

我已经使用程序youtube-dl下载了一个YouTube播放列表，我选择了单独下载视频和音频，我现在有一个文件夹充满了视频及其相应的音频，我希望与ffmpeg合并在一起。

我需要使用批处理脚本来执行此操作，但问题是youtube-dl在原始文件的标题之后添加了临时字母，因此视频与其对应的音频没有相同的名称，文件名如下所示：

First title in the playlist 5J34JG.mp4
First title in the playlist H3826D.webm
Second title in the playlist 3748JD.mp4
Second title in the playlist 6SHJFZ.webm

如何使用windows批处理脚本和ffmpeg合并这些多个视频/音频文件？

编辑：我忘了提到. webm文件是音频文件，我有多个文件，我不能一个接一个地重命名它们。

Answer 1

因为我需要做类似的事情，所以我发布了我较短的代码来帮助其他人。

这是子文件夹中的

FOR /F "tokens=*" %%f IN ('dir /b /s F2M\*.mp4') DO ffmpeg -i "%%~dpnxf" -i "%%~dpnf.m4a" -c:v copy -c:a aac -map 0:v:0 -map 1:a:0 "F2M\%%~nf-clean.mp4"

如果你在同一个目录下做这件事

for %%f in (*.mkv) do ffmpeg -i "%%~dpnxf" -i "%%~dpnf.m4a" -c:v copy -c:a copy -map 0:0 -map 0:1 -shortest "%%~nf-remux.mp4" 

这是因为ffmpeg不在同一个文件夹中

set ffmpeg=C:\ffmpeg.exe
for %%a in (*.mkv) do "%ffmpeg%" -i "%%~dpnxf"  -i "%%~dpnf.m4a" -c:v copy -c:a copy  -map 0:0 -map 1:0 -shortest "%%~nf-remux.mp4"

只是示例代码，没有专门为OP格式化。小心使用。

Answer 2

@echo off
setlocal

set "outdir=muxed"
if not exist "%outdir%" md "%outdir%" || exit /b 1

:: Get each mp4 file and call the label to mux with webm file.
for %%A in (*.mp4) do call :mux "%%~A"
exit /b

:mux
setlocal
set "videofile=%~1"
set "name=%~n1"

:: Last token of the name is the pattern to remove.
for %%A in (%name:-=- %) do set "pattern=-%%~A"

:: Remove the pattern from the name.
call set "name=%%name:%pattern%=%%"

:: Get the webm filename.
for %%A in ("%name%-*.webm") do set "audiofile=%%~A"

:: Mux if webm file exist and output file does not exist.
if exist "%audiofile%" if not exist "%outdir%\%name%.mp4" (
    ffmpeg -i "%videofile%" -i "%audiofile%" -c copy "%outdir%\%name%.mkv"
)
exit /b

该脚本将首先制作输出目录以保存mp4文件，以便输出不会成为输入。

循环的主将获取每个mp4文件名。： mux标签以mp4文件名作为参数调用。

变量videofile存储mp4文件名，变量name只存储名称，不带扩展名。

name的最后一个标记将是YTID模式，而for循环将最后一个标记设置为pattern。

调用集将用名称中的“”替换模式。这将提供一个可以与通配符一起使用的名称，以查找webm文件名。for循环将获得webm文件名。

如果目标确实存在，而不是输出文件，那么ffmpeg将把这两个文件多路复用到一个输出文件中。

输出文件容器格式为mkv。