为什么MessageBox对SuppressKeyPress有影响？

Question

下面是vb中的一个特殊情况。我搞乱了SuppressKeyPress属性，发现了一些奇怪的东西。

形势

假设我有一个名为txtName的输入框，我希望名称不带任何数字，当插入数字时，会弹出一个MessageBox并报告错误。

Private Sub TextBox1_KeyDown(sender As Object, e As System.Windows.Forms.KeyEventArgs) Handles txtName.KeyDown
    If e.KeyCode >= Keys.D0 And e.KeyCode <= Keys.D9 And _
e.Modifiers <> Keys.Shift Then
        e.SuppressKeyPress = True
        MsgBox("Error - A Number has been pressed")
        'The number appeared in the text box.
    End If
End Sub

在这种情况下，由于某种奇怪的原因，如果我键入一个数字，它将被写入文本框中，尽管我抑制了按键。

我发现，如果我删除MsgBox行，数字将不会出现在输入框中。

Private Sub TextBox1_KeyDown(sender As Object, e As System.Windows.Forms.KeyEventArgs) Handles txtName.KeyDown
    If e.KeyCode >= Keys.D0 And e.KeyCode <= Keys.D9 And _
e.Modifiers <> Keys.Shift Then
        e.SuppressKeyPress = True
        'The number did not appear in the text box.
    End If
End Sub

问题

这是怎么回事？为什么MsgBox“允许”按键被按下？为什么它对SubpressKeyPress属性有任何影响？

Answer 1

所以我测试了你的代码，我可以重现这种行为。我认为之所以会发生这种情况，是因为MsgBox（一个模式对话框）将调用应用程序。DoEvents导致消息被处理。

通过替换

MsgBox("Error - A Number has been pressed")

与

Application.DoEvents

你会得到同样的结果。

你应该在下面的帖子中阅读汉斯·帕桑的答案。他很好地解释了ShowDialog（参考MsgBox）和DoEvents之间的关系。

• 应用程序的使用。DoEvents（）

Answer 2

我为那些不想干扰调用方法、手动启动新线程等的人找到了一个小技巧。

我的（旧）代码不起作用了

Private Sub textEditKeyPress(ByVal sender As Object, ByVal e As KeyEventArgs)
    If e.KeyValue = 220 Then
        e.SuppressKeyPress = True
        MessageBox.Show("\ not allowed. Use / instead.")
    End If
End Sub

通过将代码更改为

Private Async Sub tEditDropBoxFolderName_EditValueChanged(ByVal sender As Object, ByVal e As KeyEventArgs)
    If e.KeyValue = 220 Then
        e.SuppressKeyPress = True
        Await Task.Delay(100)
        MessageBox.Show("\ not allowed. Use / instead.")
    End If
End Sub

一切正常，我没有发现使用这个有任何副作用。

（代码由c#翻译，可能需要对vb进行一些修改。）

Answer 3

这是使用MessageBox的一个非常典型的副作用，它可能会导致许多棘手的诊断问题。通过在消息队列中搜索任何按键事件并将其删除来实现SubpressKeyPress属性。但这只能在事件处理程序完成后发生。

问题是，它不会很快完成。您的MsgBox（）调用正在接管，它开始自行泵送消息循环。就像对话框一样，相当于调用臭名昭著的DoEvents（）方法。它会很容易地调度消息队列中的挂起消息，包括那些应该被抑制的按键消息。

解决此类问题的一个创可贴是在事件处理完成并且Winforms有机会清除按键消息后，稍后显示消息框。通过使用控件优雅地完成。BeginInvoke（）方法：

Private Sub TextBox1_KeyDown(sender As Object, e As KeyEventArgs) Handles TextBox1.KeyDown
    If e.KeyCode >= Keys.D0 And e.KeyCode <= Keys.D9 And e.Modifiers <> Keys.Shift Then
        e.SuppressKeyPress = True
        Me.BeginInvoke(New Action(Sub() MsgBox("Error - A Number has been pressed")))
    End If
End Sub

但真正的解决方法是使用正确的事件。您应该始终使用KeyPress事件来进行这种过滤。这也避免了在您使用KeyDown时始终存在的对用户活动键盘布局的非常痛苦的依赖。修复：

Private Sub TextBox1_KeyPress(sender As Object, e As KeyPressEventArgs) Handles TextBox1.KeyPress
    If e.KeyChar >= "0"c AndAlso e.KeyChar <= "9"c Then
        e.Handled = True
        MsgBox("I don't like digits")
    End If
End Sub

但话说回来，不要因为用户犯了一个简单的错误而使用消息框来打他耳光。