要求期望的输入成为一个代理或代理集，但没有得到任何人

Question

在我的研究中，我试图构建一个代表真实工作环境的模拟，目的是创造关于如何让人们在工作中感觉更好的知识。特别是，我正在模拟一个人们为多个团队工作的场景（你一次只从事一个项目吗？许多人不...）。为此，我正在使用NetLogo。

我在向定制链接乌龟集的特定代理询问时遇到问题。关键是，有时它会报告一个错误，说“请求期望的输入成为一个代理或代理集，但却没有得到任何人”，但如果代理不存在，它就不应该到达“请求”状态！我做错了什么？

功能如下：

to TeamRecruiting
  ;; I ask non-complete teams to...
  ask teams with [ teamsize != (count membership-neighbors) ]
  [
    ;; ... count how many individuals they have...
    let actualteammembers count membership-neighbors
    ;; ... to save locally how many individuals they can share...
    let teamoverlap overlap
    ;; ... their target size...
    let neededsize teamsize
    ;; ... and their identity.
    let teamwho who
    ;; then I ask those individuals that have not yet more things than they can handle...
    ask individuals with [ indMTM != (count membership-neighbors) ]
      [
      ;; ... to save locally who they are...
      let indwho who
      let createdalink 0
      ;; ... then if some conditions have been met ...
      if(some conditions)
        [
        ;; I create a link (of my specific type) with the team...
        create-membership-with team teamwho
        ;; I do the following because more than one individual could join the team teamwho in the same run of the function
        ask team teamwho [ set actualteammembers (actualteammembers + 1) ]
        set createdalink 1
        ]
      ;; if the association occurred, ...
      if(createdalink = 1)
        [
        ;; we ask all other teams to evaluate if the new connection violates their maximum overlap constraint between the team I am considering from the beginning of the function, and all other teams, in other words...
        ask teams with [ who != teamwho ]
        [
        let numpaths 0
        let team2who who
        ;; I count how many individuals say that they are shared by the two teams
        ask individuals
          [
          if((membership-neighbor? team teamwho) and (membership-neighbor? team team2who)) [ set numpaths (numpaths + 1) ]
          ]
        ;; ... and if the number of paths is more than the maximum allowed overlap...
        if(numpaths > teamoverlap)
          [
          ;; I take the connection away...
          ask membership teamwho indwho [ die ]
          ;; and I reduce the actual number of team members
          set actualteammembers (actualteammembers - 1)
          ]
        ]
      ]
    ]
  ]
end

谢谢你宝贵的帮助！

Answer 1

我认为问题很可能在于你引用你请求的链接的方式membership是一个无向链接，因此哪个代理是end1，哪个是end2取决于代理的创建顺序。who编号较低的一个是end1，另一个是end2。因此，如果团队代理是在个人代理之后创建的，那么特定的链接将是membership indwho teamwho。总的来说，使用世卫组织的数字是不好的做法，但如果你使用团队和个人代理人本身，而不是他们的世卫组织数字，同样的问题也会出现。

在使用无向链接方面比我更有经验的人可能会有更好的建议，当你不知道哪个代理更老时，如何轻松地引用无向链接，但类似于

ifelse (indwho < teamwho) [
ask membership indwho teamwho [ die ]
]
[
ask membership teamwho indwho [ die ]
]

应该有用。使用定向链接可以避免此问题，因为创建者代理始终是end1，而目标代理始终是end2。因此，如果会员链接总是由个人创建的，那么您将始终知道个人位于end1。

希望这有帮助。查尔斯