为什么在Julia中用户定义的类型和内置的语言类型一样快速和紧凑？

Question

我已经审查了很多文档，但我找不到一个具体的答案。

Julia标准基元类型都是在语言本身中定义的，Julia允许您声明自己的基元类型，但我不知道这是否是为什么程序员定义的类型像内置类型一样快速和紧凑的原因。我甚至检查了GitHub上的源代码，更具体地说是bool.jl，这是定义int等数值类型的地方，但我不敢猜测。有人能给我一个具体的答复吗？谢了。

Answer 1

这是一个很难精确回答并涵盖所有角落情况的问题。

以下是我对一个简单（希望不要过于简化）的解释：

1. Julia代码被编译为下一次执行的本机程序集指令。
2. 如果Julia编译器能够证明两个实现是等效的，那么您可以预期将为这两个实现生成相同的本机程序集指令（这不是100%正确，但根据我的经验，这是一个很好的近似值）。
3. 这意味着在本机程序集级别上，只要要执行的操作和编译器拥有的类型信息相同，使用的类型（内置的或自己的）并不重要。

struct A
    a::Int
end

function f(x::Int, n)
    s = Int[]
    for i in 1:n
        push!(s,x)
    end
    s
end

function f(x::A, n)
    s = Int[]
    for i in 1:n
        push!(s,x.a)
    end
    s
end

function f2(x::A, n)
    s = A[]
    for i in 1:n
        push!(s,x)
    end
    s
end

现在，如果您运行@code_native f(1，10^6)、@code_native f(A(1)，10^6)和@code_native f2(A(1)，10^6)，您将看到生成的代码（几乎）相同。

您可以在基准测试中看到这一点的效果：

julia> using BenchmarkTools

julia> @btime f(1, 10^6);
  8.567 ms (20 allocations: 9.00 MiB)

julia> @btime f(A(1), 10^6);
  8.528 ms (20 allocations: 9.00 MiB)

julia> @btime f2(A(1), 10^6);
  8.446 ms (20 allocations: 9.00 MiB)

您有相同的时间和相同的分配数量。

struct C
    a
end

function f(x::C, n)
    s = Int[]
    for i in 1:n
        push!(s,x.a)
    end
    s
end

julia> @btime f(C(1), 10^6);
  19.855 ms (21 allocations: 9.00 MiB)