Oracle-ORA-06502:PL/SQL:数值或值错误(DBMS_OUTPUT)

Question

我实现了一个返回clob数据类型的函数，我希望在DBMS输出中打印结果。不幸的是，我得到了ORA-06502:PL/SQL:numeric或value错误，我认为这是由于dbms_output的大小造成的。

这是密码。

DECLARE

    TYPE tp_col_array IS TABLE OF varchar2(32767); 
    FUNCTION my_fn (        
        p_in_proc_date IN varchar2)
        RETURN clob AS         
         vr_output_str clob;

        BEGIN            

        -- Detailed code hidden due to privacy. Sorry

        RETURN vr_output_str;

        EXCEPTION 
            WHEN LOGIN_DENIED
            THEN 
                DBMS_OUTPUT.PUT_LINE('Invalid username/password: logon denied');
        RETURN 'TEST Terminated';

    END my_fn;

BEGIN
    DBMS_OUTPUT.PUT_LINE(my_fn('31-AUG-14'));    
END;

这里有一些东西可以帮助您理解这个问题
1)添加了以下内容来设置缓冲区的大小不受限制，但不起作用…

DBMS_OUTPUT.ENABLE(NULL);

set serveroutput on size unlimited;

DBMS_LOB.getlength(vr_output_str); // =75387

3）我可以通过执行以下操作来解决这个问题，但我认为这不是一个好的解决方案，因为它执行了三次函数。

DBMS_OUTPUT.PUT_LINE(SUBSTR(my_fn ('31-AUG-14'), 1, 32767));
DBMS_OUTPUT.PUT_LINE(SUBSTR(my_fn ('31-AUG-14'), 32768, 32767));
DBMS_OUTPUT.PUT_LINE(SUBSTR(my_fn ('31-AUG-14'), 65536, 32767));

4）我使用的是Oracle数据库11g企业版11.2.0.3.0-64bit产品

Answer 1

如果clob大于32767字节，则不能直接使用dbms_output.put_line打印clob。

如果是这种情况，您可以创建一个过程来遍历clob，并每次打印出一个较小的块。下面是这样一个过程和测试脚本：

declare 

  c clob;

  procedure print_clob( p_clob in clob ) is
      v_offset number default 1;
      v_chunk_size number := 10000;
  begin
      loop
          exit when v_offset > dbms_lob.getlength(p_clob);
          dbms_output.put_line( dbms_lob.substr( p_clob, v_chunk_size, v_offset ) );
          v_offset := v_offset +  v_chunk_size;
      end loop;
  end print_clob;


begin
  for i in 1..10000 loop
     c := c || 'test';
  end loop;
  --This will result in ora-06502
  --dbms_output.put_line(c);

  print_clob(c);

end;

请注意，v_chunk_size每次分块的字节必须少于32767字节。如果编码每个字符有2个字节，则需要使用（32767/2）。