如何截断德尔福组合框中选定的文本？

Question

我有一个组合框，其样式设置为csDropDown。我试图在OnSelect事件处理程序中做到这一点；

if cboEndTime.ItemIndex > -1 then
  cboEndTime.Text := AnsiLeftStr(cboEndTime.Text, 5);

但它没有效果。

组合项目如下所示；

09:00（0分钟）
09:30（30分钟）
10:00（1小时）
10:30（1.5小时）
。。。

例如，如果我选择第二项，我希望组合框的文本显示为09:30，即截断。这会将ItemIndex设置为-1。

我怎样才能做到这一点？

Answer 1

您可以将样式设置为OwnerDraw修复，并使用OnDrawItem自己绘制希望的文本。本示例中的查找将显示所有，所选内容仅显示修剪过的字符串。

procedure TForm3.ComboBox1DrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);

  var
   C:TComboBox;

  Function Strip(const s:String):String;
    begin
       if C.DroppedDown then result := s
       else Result := Copy(s,1,pos('(',s)-1);
    end;
begin
     C := TComboBox(Control);
     C.Canvas.FillRect(Rect);
     C.Canvas.TextOut(Rect.left + 1,Rect.Top + 1, Strip(C.Items[Index] ));
end;

Answer 2

您在OnSelect事件中对Text所做的更改似乎随后会被框架覆盖。不管是Windows API还是VCL，我还没有研究哪个。

一种解决方案是推迟实际更改，直到原始输入事件的处理完成。像这样：

const
  WM_COMBOSELECTIONCHANGED = WM_USER;

type
  TForm1 = class(TForm)
    ComboBox1: TComboBox;
    procedure ComboBox1Select(Sender: TObject);
  protected
    procedure WMComboSelectionChanged(var Msg: TMessage); message WM_COMBOSELECTIONCHANGED;
  end;

implementation

{$R *.dfm}

procedure TForm1.ComboBox1Select(Sender: TObject);
begin
  PostMessage(Handle, WM_COMBOSELECTIONCHANGED, 0, 0);
end;

procedure TForm1.WMComboSelectionChanged(var Msg: TMessage);
begin
  if ComboBox1.ItemIndex<>-1 then
  begin
    ComboBox1.Text := Copy(ComboBox1.Text, 1, 1);
    ComboBox1.SelectAll;
  end;
end;