Kotlin Spring Boot注释处理“无法解决配置处理”

Question

我无法在我的Kotlin Spring Boot应用程序中正确地注入@value应用程序属性。在我的application.yml文件中定义并随后在aderator-spring-configuration-metadata.json文件中引用的属性（在resources->META-INF下）没有正确地添加到bean表达式上下文中。使用IntelliJ Version2020.2.1，当我将鼠标悬停在该属性上时，我会看到无法解析配置属性错误。试图运行应用程序（将配置属性值construction-inject到类中）会导致通过构造函数参数表示的不满足依赖项错误。

plugins {
    id("org.springframework.boot") version "2.3.3.RELEASE"
    id("io.spring.dependency-management") version "1.0.10.RELEASE"
    kotlin("jvm") version "1.3.72"
    kotlin("plugin.spring") version "1.3.72"
}

group = "com.myProject"
version = "0.0.1-SNAPSHOT"
java.sourceCompatibility = JavaVersion.VERSION_11

repositories {
    mavenCentral()
}

extra["springCloudVersion"] = "Hoxton.SR8"

dependencies {
    implementation("org.springframework.boot:spring-boot-starter-webflux")
    implementation("com.fasterxml.jackson.module:jackson-module-kotlin")
    implementation("io.projectreactor.kotlin:reactor-kotlin-extensions")
    implementation("org.springframework.boot:spring-boot-configuration-processor:2.3.3.RELEASE")
    implementation("org.jetbrains.kotlin:kotlin-reflect")
    implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8")
    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-reactor")
    testImplementation("org.springframework.boot:spring-boot-starter-test") {
        exclude(group = "org.junit.vintage", module = "junit-vintage-engine")
    }
    testImplementation("io.projectreactor:reactor-test")
}

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath("com.google.cloud.tools:appengine-gradle-plugin:2.2.0")
    }
}

apply(plugin = "com.google.cloud.tools.appengine")

configure<com.google.cloud.tools.gradle.appengine.appyaml.AppEngineAppYamlExtension> {
    deploy {
        projectId = "my-cloud-project"
        version = "GCLOUD_CONFIG"
    }
}

dependencyManagement {
    imports {
        mavenBom("org.springframework.cloud:spring-cloud-dependencies:${property("springCloudVersion")}")
    }
}

tasks.withType<Test> {
    useJUnitPlatform()
}

tasks.withType<KotlinCompile> {
    kotlinOptions {
        freeCompilerArgs = listOf("-Xjsr305=strict")
        jvmTarget = "11"
    }
}

{
  "properties": [
    {
      "name": "otherApi.baseUrl",
      "type": "java.lang.String",
      "description": "Description for otherApi.baseUrl."
    }
  ]
}

我已经添加了注释处理依赖项，使缓存失效并重新启动，并使用了Kotlin特定的注释处理器（kapt）。我还按照下面的说明进行了操作：https://www.jetbrains.com/help/idea/annotation-processors-support.html

我错过了什么？任何帮助都将不胜感激。谢了！




Answer 1

您需要将以下内容声明为AnnoatationProcessor

implementation("org.springframework.boot:spring-boot-configuration-processor:2.3.3.RELEASE")

到

annotationProcessor("org.springframework.boot:spring-boot-configuration-processor:2.3.3.RELEASE")