jar文件中没有主清单属性

Question

我已经看了几个不同的线程，没有找到解决方案。我做了一个项目，使用java和Gradle从google sheets检索数据。我已经创建了一个工件，并通过IntelliJ构建了jar文件。当我尝试使用“java-jar filename.jar”通过终端运行jar时，我得到“no main manifest attribute,in filename.jar”

My Manifest.mf位于main/java/meta-inf中，具有以下简单结构

Manifest-Version: 1.0
Main-Class: Main

build.gradle文件具有以下结构：

plugins {
    id 'java'
}

group  'filename'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
    compile 'com.google.api-client:google-api-client:1.30.4'
    compile 'com.google.oauth-client:google-oauth-client-jetty:1.30.4'
    compile 'com.google.apis:google-api-services-sheets:v4-rev581-1.25.0'
}

显然，我已经说明了main方法是什么类，这就是为什么这个errormessage对我来说没有意义的原因。有人对此有解决办法吗？

Answer 1

我遵循了Sheets API quickstart中的步骤来设置应用程序。之后，我按照另一个答案中的步骤生成.jar文件，这说明您应该在jar属性中的build.gradle文件中声明清单文件。

之后，当运行生成的.jar文件时，我得到了一个“无效签名文件”错误，我可以通过在jar属性中添加下面一行来修复这个错误，如下所述：

exclude 'META-INF/*.RSA', 'META-INF/*.SF','META-INF/*.DSA'

生成.jar文件后，您可以在项目的build/libs目录中找到它。我的endbuild.gradle文件如下所示：

apply plugin: 'java'
apply plugin: 'application'

group 'egs'
version '1.0-SNAPSHOT'

mainClassName = 'SheetsQuickstart'
sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
    compile 'com.google.api-client:google-api-client:1.30.4'
    compile 'com.google.oauth-client:google-oauth-client-jetty:1.30.4'
    compile 'com.google.apis:google-api-services-sheets:v4-rev581-1.25.0'
}

jar {
    manifest {
        attributes 'Main-Class': 'SheetsQuickstart'
    }
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    exclude 'META-INF/*.RSA', 'META-INF/*.SF','META-INF/*.DSA'
}