ANTLR4语法-字段和扩展表达式中带“点”的问题

Question

我有以下ANTLR4语法

grammar ExpressionGrammar;

parse: (expr)
     ;

expr: MIN expr
    | expr ( MUL | DIV ) expr
    | expr ( ADD | MIN ) expr
    | NUM
    | function
    | '(' expr ')'
    ;

function : ID '(' arguments? ')';

arguments: expr ( ',' expr)*;

/* Tokens */

MUL : '*';
DIV : '/';
MIN : '-';
ADD : '+';
OPEN_PAR : '(' ;
CLOSE_PAR : ')' ;

NUM : '0' | [1-9][0-9]*;
ID : [a-zA-Z_] [a-zA-Z]*;
COMMENT: '//' ~[\r\n]* -> skip;
WS: [ \t\n]+ -> skip;

(Fields.V1)*(Fields.V2) + (Constants.Value1)*(Constants.Value2)

(FieldsV1)*(FieldsV2)+(Constants<missing ')'> 

除此之外还有一个问题：-

 (Var1)(Var2)    

对于上面的场景，ANTLR没有抛出错误，表达式不应该是(Var1)(Var2)--它应该总是包含操作符(Var1)*(Var2)或(Var1)+(Var2)等。解析器错误树没有生成此错误。如何修改语法以确保即使是这种情况也被考虑在内。

Answer 1

若要识别ID类似于fields.v1，请将ID的Lexer规则更改为如下所示：

fragment ID_NODE: [a-zA-Z_][a-zA-Z0-9]*;
ID: ID_NODE ('.' ID_NODE)*;

注意，由于ID的每个“节点”都遵循相同的规则，所以我将其作为一个lexer片段，可以用来组成ID规则。我还在片段的第二部分添加了0-9，因为您似乎希望允许IDs中的数字

然后，ID规则使用该片段构建Lexer规则，该规则允许ID中的点。

处理两个示例的修订版：

grammar ExpressionGrammar;

parse: expr EOF;

expr:
    MIN expr
    | expr ( MUL | DIV) expr
    | expr ( ADD | MIN) expr
    | NUM
    | ID
    | function
    | '(' expr ')';

function: ID '(' arguments? ')';

arguments: expr ( ',' expr)*;

/* Tokens */

MUL: '*';
DIV: '/';
MIN: '-';
ADD: '+';
OPEN_PAR: '(';
CLOSE_PAR: ')';

NUM: '0' | [1-9][0-9]*;
fragment ID_NODE: [a-zA-Z_][a-zA-Z0-9]*;
ID: ID_NODE ('.' ID_NODE)*;
COMMENT: '//' ~[\r\n]* -> skip;
WS: [ \t\n]+ -> skip;

（现在我已经阅读了评论，这几乎只是应用评论中的建议）