为什么我的antlr语法似乎正确地解析了这个输入？

Question

grammar ParserLang;

options {
    language=Python;
}

@header {
import sys
import antlr3

from ParserLangLexer import ParserLangLexer
}

@main { 
def main(argv, otherArg=None):
    char_stream = antlr3.ANTLRInputStream(open(sys.argv[1],'r'))
    lexer = ParserLangLexer(char_stream)

    tokens = CommonTokenStream(lexer)
    parser = ParserLangParser(tokens);

    rule   = parser.entry_rule()
}

program     : idList EOF
            | integerList EOF
            ;

idList      : ID whitespace idList 
            | ID
            ;

integerList : INTEGER whitespace integerList 
            | INTEGER
            ;

whitespace  : (WHITESPACE | COMMENT) +;

ID            : LETTER (DIGIT | LETTER)*;
INTEGER       : (NONZERO_DIGIT DIGIT*) | ZERO ;
WHITESPACE    : ( '\t' | ' ' | '\r' | '\n'| '\u000C' )+    { $channel = HIDDEN; } ;
COMMENT       : ('/*' .* '*/') | ('//' .* '\n') { $channel = HIDDEN; } ;

fragment ZERO            : '0' ;
fragment DIGIT         : '0' .. '9';
fragment NONZERO_DIGIT : '1' .. '9';
fragment LETTER        : 'a' .. 'z' | 'A' .. 'Z';

编辑：当我使用ANTLRWorks以相同的语法输入时，会抛出一个NoViableAltException。我如何通过代码得到错误？

Answer 1

我无法复制它。当我在修复语法错误(rule=parser.entry_rule()应该是:rule=parser.program())之后从输入生成lexer和parser，并解析输入“12月12日1965”（作为文件输入或作为纯字符串）时，我会得到以下错误：

line 1:0 no viable alternative at input u'December'

这可能看起来很奇怪，因为这可能是IDList的开始。事实是，你的语法还有一个错误，还有一个可以改进的小地方：

• 空白和注释放置在隐藏通道上，因此在解析器规则中不可用（至少不更改解析器读取其标记的通道...）；
• 输入末尾的注释，即末尾没有\n，将无法正确标记。最好定义这样的一行注释:'//'~('\r''\n')*。尾部的换行符终究会被空白规则捕获。

由于空白规则，解析器无法匹配IDList（或IntegerList)，因此会产生指向第一个令牌的错误('decce')。

下面是一个有效的语法（如预期的那样）：

grammar ParserLang;

options {
    language=Python;
}

@header {
import sys
import antlr3

from ParserLangLexer import ParserLangLexer
}

@main { 
def main(argv, otherArg=None):
    lexer = ParserLangLexer(antlr3.ANTLRStringStream('December 12 1965'))
    parser = ParserLangParser(CommonTokenStream(lexer))
    parser.program()
}

program     : idList EOF
            | integerList EOF
            ;

idList      : ID+
            ;

integerList : INTEGER+
            ;

ID          : LETTER (DIGIT | LETTER)*;
INTEGER     : (NONZERO_DIGIT DIGIT*) | ZERO ;
WHITESPACE  : ( '\t' | ' ' | '\r' | '\n'| '\u000C' )+ { $channel = HIDDEN; } ;
COMMENT     : ('/*' .* '*/' | '//' ~('\r' | '\n')*)   { $channel = HIDDEN; } ;

fragment ZERO          : '0' ;
fragment DIGIT         : '0' .. '9';
fragment NONZERO_DIGIT : '1' .. '9';
fragment LETTER        : 'a' .. 'z' | 'A' .. 'Z';

运行从上面的语法生成的解析器也会产生错误：

line 1:9 missing EOF at u'12'