一个Cypher查询中的多个LOAD CSV语句

Question

// User nodes
LOAD CSV WITH HEADERS
FROM 'file:///profile.csv' AS profile_line
CREATE (user:User { userId: profile_line.User })

// Project nodes
LOAD CSV WITH HEADERS
FROM 'file:///project.csv' AS project_line
CREATE (project:Project { projectId: project_line.projectId })

// Image nodes
LOAD CSV WITH HEADERS
FROM 'file:///media.csv' AS image_line
CREATE (image:Image { imageId: '<imageId>' })

“CREATE和LOAD CSV之间需要WITH（第9行，第1列（偏移量：211））”CREATE（project：project{projectid:project_line.projectID}）“

我不清楚WITH语句应该如何构造。

Answer 1

如果您使用的是Neo4j浏览器，最简单的方法就是用分号分隔语句，然后打开“多语句查询编辑器”（当每个语句运行时，它还会给您一个很好的小进度指示器）：

LOAD CSV WITH HEADERS
FROM 'file:///profile.csv' as profile_line
CREATE (user: User { userId: profile_line.User });

LOAD CSV WITH HEADERS
FROM 'file:///project.csv' as project_line
CREATE (project: Project { projectId: project_line.projectId });

LOAD CSV WITH HEADERS
FROM 'file:///media.csv' as image_line
CREATE (image: Image { imageId: image_line.ImageId });

否则，仍有可能做到这一点。我们想要的是一个WITH语句，它将返回单行，而不管上一个CREATE最终创建了多少节点，所以任何聚合函数都可以。例如：

LOAD CSV WITH HEADERS
FROM 'file:///profile.csv' as profile_line
CREATE (user: User { userId: profile_line.User })

WITH max(1) as dummy
LOAD CSV WITH HEADERS
FROM 'file:///project.csv' as project_line
CREATE (project: Project { projectId: project_line.projectId })

WITH max(1) as dummy
LOAD CSV WITH HEADERS
FROM 'file:///media.csv' as image_line
CREATE (image: Image { imageId: image_line.ImageId })

Added 9 labels, created 9 nodes, set 9 properties, completed after 17 ms.

尽管我认为这对未来来说是超级不清楚的--你，我不建议你这么做。