VBA：变异数组与类型化数组与非键控集合的迭代速度

Question

Dim myObject As MyClass
Set myObject = variantList.Get(i)

另外，第二个选项会比使用非键控集合更快吗？我读到收集迭代很慢，它们是为查找而设计的。这适用于非键控集合，还是仅适用于键值映射集合？

感谢任何能提供建议的人。

Answer 1

我听从了蒂姆·威廉姆斯的建议，做了一些速度测试。

对于每种类型的集合/数组，我首先添加了100,000个类“SpeedTester”的对象，它只是一个shell对象，包含一个长变量（具有get/set属性）。变量的值是循环索引的值（介于1和100,000之间）

然后我执行了第二个循环，其中涉及访问集合/数组中的每个对象，并将对象的long属性值赋给类型为long的新变量。我对每个方法执行3轮，并平均and和get循环的时间。

Method                      Avg Add Time    Avg Get Time    Total Time
Collection Indexed             0.305          25.498         25.803
Collection Mapped              1.021           0.320          1.342
Collection Indexed For Each    0.334           0.033          0.367
Collection Mapped For Each     1.084           0.039          1.123
Dynamic Array Typed            0.303           0.039          0.342
Static Array Typed             0.251           0.016          0.266

Dynamic array typed是一个自定义类，包含SpeedTester类型的数组。每次添加变量时，数组的大小将扩大1个槽（使用ReDim Proprese）。get-loop是一个for循环，使用1到100,000的索引，这是数组的典型情况。

最后，输入的静态数组只是一个SpeedTester类型的数组，它的初始值为100,000个插槽。显然这是最快的方法。奇怪的是，它的速度增长很大程度上是在获取而不是添加。由于需要调整大小，我假设其他方法的添加速度会更慢，而获取每个对象的速度不会比动态数组快。

我对使用for-loop和for-each loop访问索引集合的对象之间的差异感到惊讶。我还对映射集合的键查找速度感到惊讶--比索引快得多，可以与除静态数组之外的所有其他方法媲美。

编辑：测试本身的代码（使用动态数组）

Public Sub TestSpeed()
    Dim ts As Double
    ts = Timer()

    Dim c As TesterList
    Set c = New TesterList

    Dim aTester As SpeedTester

    Dim i As Long
    For i = 1 To 100000
        Set aTester = New SpeedTester
        aTester.Number = i

        Call c.Add(aTester)
    Next i

    Dim taa As Double
    taa = Timer()

    For i = c.FirstIndex To c.LastIndex
        Set aTester = c.Item(i)

        Dim n As Long
        n = aTester.Number
    Next i

    Dim tag As Double
    tag = Timer()

    MsgBox "Time to add: " & (taa - ts) & vbNewLine & "Time to get: " & (tag - taa)
End Sub

对于动态数组类TesterList：

Private fTesters() As SpeedTester

Public Property Get FirstIndex() As Long
    On Error GoTo Leave

    FirstIndex = LBound(fTesters)

Leave:
    On Error GoTo 0
End Property

Public Property Get LastIndex() As Long
    On Error GoTo Leave

    LastIndex = UBound(fTesters)

Leave:
    On Error GoTo 0
End Property

Public Sub Add(pTester As SpeedTester)
    On Error Resume Next

    ReDim Preserve fTesters(1 To UBound(fTesters) + 1) As SpeedTester
    If Err.Number <> 0 Then
        ReDim fTesters(1 To 1) As SpeedTester
    End If

    Set fTesters(UBound(fTesters)) = pTester

    On Error GoTo 0
End Sub

Public Function Item(i As Long) As SpeedTester
    On Error GoTo Leave

    Set Item = fTesters(i)

Leave:
    On Error GoTo 0
End Function

最后，非常简单的SpeedTester对象类：

Private fNumber As Long

Public Property Get Number() As Long
    Number = fNumber
End Property

Public Property Let Number(pNumber As Long)
    fNumber = pNumber
End Property