处理中的多个草图窗口

Question

我目前正在研究一种数据可视化技术，它从电影中获取信息，实时播放并同时创建。为此，我想有两个独立的草图窗口。一个窗口应显示实时播放的电影，另一个窗口应显示正在进行的可视化。

我似乎不知道如何轻松地添加另一个草图窗口，并尝试了一些在处理3中不再工作的示例。

然后我偶然发现了这个例子：https://gist.github.com/atduskgreg/666e46c8408e2a33b09a

尽管我可以让它一次显示两个草图窗口，但我显然不能在另一个窗口上使用来自一个窗口的数据。

还有别的方法吗？

非常感谢。

Answer 1

没有什么可以阻止您在PWindow类（创建第二个窗口）中声明一个函数，该类接受可以在内部使用的参数，并从另一个草图调用它。

因此，您可以将表单中的数据作为函数参数传递到第二个窗口。

这个小例子通过一个函数（这里称为evokedFrom主）将相对的mousePmed位置从第一个窗口传递到第二个窗口，并将其存储在一个ArrayList中，该函数将它们绘制在第二个窗口中：

PWindow win;

public void settings() {
  size(320, 240);
}

void setup() { 
  win = new PWindow();
}

void draw() {
  background(255, 0, 0);
  text("Click in this window to draw at a relative position in the other window", 10, 10, this.width - 20, 100);
}

void mousePressed() {
  println("mousePressed in primary window");
  float relPosX = map(mouseX, 0, this.width, 0, 100);
  float relPosY = map(mouseY, 0, this.height, 0, 100);
  win.evokedFromPrimary(relPosX, relPosY);
}  

class PWindow extends PApplet {
  ArrayList<PVector> vectors = new ArrayList<PVector>();
  PWindow() {
    super();
    PApplet.runSketch(new String[] {this.getClass().getSimpleName()}, this);
  }

  void evokedFromPrimary(float relPosX, float relPosY) {
    println("evoked from primary");

    float xPos = map(relPosX, 0, 100, 0, this.width);
    float yPos = map(relPosY, 0, 100, 0, this.height);

    vectors.add(new PVector(xPos, yPos));
  }
  void settings() {
    size(500, 200);
  }

  void setup() {
    background(150);
  }

  void draw() {
    background(150);
    //store the vector size before using to avoid ConcurrentModificationException
    int listLength = vectors.size();
    for(int i = 0; i < listLength; i++) {
      PVector v = vectors.get(i);
      ellipse(v.x, v.y, random(50), random(50));
    }

  }

  void mousePressed() {
    println("mousePressed in secondary window");
  }
}

这里的pWindows代码是相同的。pda文件。