类中的平台在被调用时不移动

Question

为了大学课程，我正在和一个朋友做一个游戏。一般的想法是，我们有一些平台从右向左移动，每次一个平台离开屏幕时，它都会在右侧随机的x和y位置生成（在一定范围内）。会有一个小精灵从一个平台跳到另一个平台。

我们遇到了一个不确定如何解决的问题。我们有所有正确的代码和一切，但平台就是不动。它们应该以每帧-4像素的恒定速度向左移动（rectVel没错）。

然而，我们无法让它们移动；它们在屏幕上的位置是静态的，每个人最初被呼叫的位置。

这是我能做的最简洁的代码：

Platforms [] mainPlats;

void setup() {
  size(750, 400);

  mainPlats = new Platforms[3];
}

void draw() {
  level();
}

void level() {

  //This is the code for the first platform
  mainPlats[0] = new Platforms(200, 200, 100, 15); //These values need to be     set inside the class so that
  //they aren't constantly overwriting the movement variables in the class
  mainPlats[0].displayPlat();
  mainPlats[0].platTransition();


  //This is the code for the second platform
  mainPlats[1] = new Platforms(420, 300, 100, 15);
  mainPlats[1].displayPlat();
  mainPlats[1].platTransition();


  //This is the code for the third platform
  mainPlats[2] = new Platforms(570, 350, 100, 15);
  mainPlats[2].displayPlat();
  mainPlats[2].platTransition();
}

class Platforms {
  PImage platform;
  int rectX, rectY, rectWidth, rectHeight;
  int rectVelocity = 4;

  Platforms(int x, int y, int w, int h) {
    rectX = x; 
    rectY = y;
    // rectX = (int(random(600, 800))); //Tried to randomise start position,     failed hilariously
    //rectY = (int(random(150, 350)));
    rectWidth = w;
    rectHeight = h;
  }

  void displayPlat() {
    platform = loadImage ("images/tiles.png");
    //imageMode(CENTER);

    image(platform, rectX, rectY, 100, 15); //rectangle platforms replaced     with images
  }

  void platMove() {
    rectX -= rectVelocity;
  }

  void platTransition() {
    if (rectX < -200) {
      rectX = (int(random(700, 1000)));
      rectY = (int(random(150, 350)));
    }
  }
 }

Answer 1

把rectX作为正值(

Answer 2

在draw（）函数中，调用level（）函数，该函数在每个帧初始化Platform数组。

这意味着您可以在每帧的起始位置创建新平台。你永远看不到平台在移动，因为一旦你移动它们，你就会在起始位置用新的平台替换它们。

第一步是将它们的初始化从level（）函数中移出，只在草图的开头调用它们一次，setup（）函数就是一个可以放置它们的地方。

你的另一个问题是，你从来没有真正调用platMove（）函数。第二步是确保调用该函数。

解决方案可能看起来像这样：

Platforms [] mainPlats;

void setup() {
  size(750, 400);

  mainPlats = new Platforms[3];
  mainPlats[0] = new Platforms(200, 200, 100, 15);
  mainPlats[1] = new Platforms(420, 300, 100, 15);
  mainPlats[2] = new Platforms(570, 350, 100, 15);
}

void draw() {
  level();
}


void level() {
  mainPlats[0].displayPlat();
  mainPlats[0].platMove();
  mainPlats[0].platTransition();

  mainPlats[1].displayPlat();
  mainPlats[1].platMove();
  mainPlats[1].platTransition();

  mainPlats[2].displayPlat();
  mainPlats[2].platMove();
  mainPlats[2].platTransition();
}

还要注意的是，你也不应该每一帧都加载图像。你应该在启动时只加载一次。您可能还希望使用for循环在平台上迭代，而不是引用每个索引。但这些并不会真正影响你的问题。