使用Kotlin Gradle DSL向Kotlin项目添加集成测试

Question

我想向Kotlin项目添加一个额外的“源代码集”，该项目将包含集成测试。我看到过一些帖子，其中谈到为香草Java项目或Kotlin做这件事，但使用Groovy而不是Kotlin Gradle DSL。

总之，使用静态编程语言Gradle DSL：

• 如何添加可以包含Kotlin代码、Java代码的附加“源代码集”

我希望目录结构看起来像：

src
   main
      java
      kotlin
      resources
   test
      java
      kotlin
      resources
   integration
      java
      kotlin
      resources

相关的：

>

https://ryanharrison.co.uk/2018/07/25/kotlin-add-integration-test-module.html

https://www.petrikainulainen.net/programming/gradle/getting-started-with-gradle-integration-testing/

如何向Gradle添加新的源集？

谢谢

Answer 1

必须将以下配置添加到生成中。梯度锉

configurations {
    integrationTestImplementation.extendsFrom implementation
    integrationTestRuntimeOnly.extendsFrom runtimeOnly
}


dependencies {
    intTestImplementation 'junit:junit:4.12'
    ...
}

sourceSets {
    integrationTest {
        kotlin {
            compileClasspath += main.output + test.output
            runtimeClasspath += main.output + test.output
            srcDir file('src/integrationTest/kotlin')
        }
    }
}

task integrationTest(type: Test, dependsOn: []) {
    testClassesDirs = sourceSets.integrationTest.output.classesDirs
    classpath = sourceSets.integrationTest.runtimeClasspath
    useJUnitPlatform()
}

来源：https://docs.gradle.org/current/userguide/java_testing.html#sec：configuring_java_integration_tests

Answer 2

首先，创建源代码集和配置：

sourceSets {
    create("intTest") {
        compileClasspath += sourceSets.main.get().output
        runtimeClasspath += sourceSets.main.get().output
    }
}

val intTestImplementation: Configuration by configurations.getting {
    extendsFrom(configurations.implementation.get())
}

val intTestRuntimeOnly: Configuration by configurations.getting {
    extendsFrom(configurations.runtimeOnly.get())
}

然后，创建要运行它们的任务：

val integrationTest = task<Test>("integrationTest") {
    description = "Runs integration tests"
    group = "verification"

    testClassesDirs = sourceSets["intTest"].output.classesDirs
    classpath = sourceSets["intTest"].runtimeClasspath
    shouldRunAfter("test")
}

此外，还可以添加要由新源集使用的依赖项。例如：

intTestImplementation("org.junit.jupiter:junit-jupiter-api:$junitVersion")
intTestRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:$junitVersion")