perl6"等待的操作"

Question

该程序创建一个线程，用dir（）读取目录，并将文件放在通道上$N个工作线程读取该通道并“处理”（打印）文件。

然而，我得到了这个“等待的第一个操作：”错误。

关于这个错误，我已经在陷阱页面上读了好几遍了，但还是没有弄明白。能解释一下这里发生了什么吗？

目录内容：

$ ls
a  b  c  traverse-dir0.p6

运行程序：

$ ./traverse-dir0.p6 
traverse-dir0.p6
a
b
c
An operation first awaited:
  in sub MAIN at ./traverse-dir0.p6 line 24
  in block  at ./traverse-dir0.p6 line 5

Died with the exception:
    Cannot find method 'path': no method cache and no .^find_method
      in block  at ./traverse-dir0.p6 line 16

程序travers-dir. p6：

#!/usr/bin/env perl6
# There is a thread to populate $dir-channel by reading filenames in a directory with dir()
# and $N worker threads to read the filenames from the $dir-channel.

sub MAIN( Str $dir = ".", Int :$N = 4 ) {

    my $dir-channel = Channel.new();
    my $dir-read = start {
        $dir-channel.send( $_ ) for dir $dir;
        $dir-channel.close;
    }

    my @workers = (^$N).map: {
        start {
            while my $file = $dir-channel.receive() {
                say $file.path;
            }
            CATCH {
                when X::Channel::ReceiveOnClosed { .resume }
            }
        }
    }

    await $dir-read, @workers;
}

Answer 1

首先，关于从wait引发的异常的输出。当异步操作失败时，有两条有趣的信息：

• 在程序中，我们希望得到操作结果的位置

第一条信息指示wait的位置，堆栈跟踪与此相关。第二部分是关于wait重新引发异常的原因，并指出需要解决的问题。

这种情况下的问题是path方法被调用到没有一个对象的对象上。这要归功于。简历，这毫无意义。引发异常，表示无法从通道接收值。恢复它只是意味着循环主体在$file中运行一个未定义的值，它缺少一个path方法并导致错误。（顺便说一句：是非常非常罕见的。简历是正确的答案。）

对代码的最小修复是替换。使用最后一个继续，当频道关闭时终止迭代：

my @workers = (^$N).map: {
    start {
        while my $file = $dir-channel.receive() {
            say $file.path;
            CATCH {
                when X::Channel::ReceiveOnClosed { last }
            }
        }
    }
}

但是，将频道强制为可编辑的Seq要简单得多。当频道关闭时，这会自动处理终止迭代的问题，因此不会出现异常：

my @workers = (^$N).map: {
    start {
        for $dir-channel.Seq -> $file {
            say $file.path;
        }
    }
}

由于start是一个语句前缀，这进一步缩短为：

my @workers = (^$N).map: {
    start for $dir-channel.Seq -> $file {
        say $file.path;
    }   
}   

我知道这可能是一个更有趣的问题的简化版本，或者可能是为了探索各种Perl 6并发性概念而做的，但是所有这些都可以替换为：

sub MAIN( Str $dir = ".", Int :$N = 4 ) {
    race for dir($dir).race(batch => 1, degree => $N) -> $file {
        say $file.path;
    }
}

它具有相同的语义学，但节省了启动和管理工人，同时仍然控制工人的数量，并确保文件在工人之间以相同的方式分发。