如何使用Excel:：Writer:：XLSX创建一个表，其中插入一行将复制列的公式？

Question

因此，在Excel中，我可以手动创建以下内容（我让它在C列中显示公式）：

然后，我可以选择A： 1到C3，选择插入-

然后，当我右键单击第3行并选择Insert时，我得到一个新的第3行，其中C列的公式复制正确。

我的问题是，我似乎无法使用Excel:：Writer:：XLSX使用Perl生成Excel文件，该文件可以创建一个表，在该表中插入一行将导致复制公式。结果是一片空白，如下所示：

下面是我的代码。任何见解都将不胜感激。

#!/usr/bin/env perl

use strict;
use warnings;

use Excel::Writer::XLSX;

my $filePath = shift;
my $workbook = Excel::Writer::XLSX->new( $filePath );
my $worksheet = $workbook->add_worksheet( 'Metadata' );

my @data = ( [1,2,"=SUM(A2:B2)"], [3,4,"=SUM(A3:B3)"], [5,6,"=SUM(A4:B4)"] );

my $rowCount = (scalar @data) + 1;

$worksheet->add_table( 
    "A1:C$rowCount", 
    {
        data => \@data,
        name => 'Table1',
        style => 'Table Style Medium 2',
        autofilter => 0,
        header_row => 1,
        columns => [
            { header => 'Value 1' },
            { header => 'Value 2' },
            { header => 'Sum' },
        ]
    }
);

$workbook->close();

Answer 1

Excel表格使用得太少了。。。很高兴看到有人对他们所能提供的东西表示赞赏，并对模块作者添加表支持表示赞赏。

有几件事。。。如果需要基于表格的公式，请在表格列的formula属性中声明它。这将导致将其复制到创建的任何新行。

{ header => 'Title', formula => '=1+2' }

其次，可能有一种方法可以通过R1C1语法实现这一点（Excel支持它，但我不知道Excel:：Writer:：XLSX是否支持），但我发现，当您引用表中的其他列时，基于表列而不是单元格引用是最容易做到的——这是Excel表相对于标准范围的一大优势。

formula => '=[@[Header A]]*[@[Header B]]'

受影响的代码应如下所示：

my @data = ( [1,2], [3,4], [5,6] );

my $rowCount = (scalar @data) + 1;

$worksheet->add_table(
    "A1:C$rowCount",
    {
        data => \@data,
        name => 'Table1',
        style => 'Table Style Medium 2',
        autofilter => 0,
        header_row => 1,
        columns => [
            { header => 'Value 1' },
            { header => 'Value 2' },
            { header => 'Sum',
              formula => '=SUM([@[Value 1]]:[@[Value 2]])'
            },
        ]
    }
);

当你打开电子表格并添加一行时，我想你会得到你想要的行为。