如何更改powerpoint幻灯片母版中的特定文本框

Question

我有一个在幻灯片母版上使用不同的母版布局的PPT。每次我们进行更新时，都需要更新特定母版幻灯片上的特定文本框。我想用一个宏来做到这一点。

我有一张幻灯片母版，标题为“幻灯片”,下面有两个版本。它有一个“通用的Bullet_slide ”,下面有10个变体。

在“通用Bullet_Slide”上有一个文本框，其中包含两行：“CONFIG.MGR： [您的姓名]， [您的代码]， [您的手机号码]“ ”文件名： [文件名]”

每次我们发送项目时，都需要手动更新[]中的字段。如果我们忘记了它的坏消息。

我已经看到了如何循环浏览所有幻灯片，然后循环所有形状以查找文本框。我能找到一个专门包含这些单词的框吗（“CONFIG.MGR：“ 和 ”文件名：“） ？

我可以只搜索“布局”幻灯片吗？我如何定位版面幻灯片上的任何内容，而不是普通幻灯片？

非常感谢。

Answer 1

您可以使用名为“ActivePresentation.Designs（x）.SlideMaster.CustomLayouts”的对象来访问SlideMaster设计中的每个自定义布局幻灯片。（您可以在一个演示文稿中拥有多个设计。）

访问自定义布局幻灯片中的子对象就像处理普通幻灯片中的对象一样。

我认为您可以尝试以下自动化代码：

Option Explicit
Option Compare Text 'Ignore Upper/Lower case

Sub UpdateCustomLayouts()

    Dim DSN As Design
    Dim CL As CustomLayout
    Dim shp As Shape
    Dim mName As String, mCode As String, mPhone As String, fName As String

    'First, change following variables before running this macro
    mName = "Your name"
    mCode = "Your code"
    mPhone = "0123456789"
    fName = ActivePresentation.Name

    'Loop each customlayouts
    For Each DSN In ActivePresentation.Designs
        For Each CL In DSN.SlideMaster.CustomLayouts
            For Each shp In CL.Shapes
                If shp.HasTextFrame Then

                    'find and update textboxes
                    With shp.TextFrame.TextRange
                        If .Text Like "CONFIG. MGR:*" Then
                            .Text = "CONFIG. MGR: " & mName & ", " & mCode & ", " & mPhone
                        ElseIf .Text Like "FILE NAME:*" Then
                            .Text = "FILE NAME: " & fName
                        End If
                    End With

                End If
            Next shp
        Next CL
    Next DSN

End Sub

正如我提到的，在运行之前首先更改“mName， mCode， mPhone， fName”等变量。