使用内部变量。幻灯片

Question

我正在开发一个交互式Powerpoint演示文稿，用户将单击照片的缩略图并能够几乎全屏查看它。我在使用.形状和.幻灯片方法时遇到了困难。

我想在演示文稿中的一张幻灯片上出现几个较小的图像。如果用户想查看非常大的图像，他们只需要单击图像。然后，我希望图像出现在它自己的新生成的幻灯片上，尽可能大。当他们单击较大的图像时，他们将被带回他们正在查看的较小图像幻灯片。这很容易实现，通过为显示中的每个小图像制作一个单独的全尺寸图像幻灯片，并在单击小图像时简单地调用大幻灯片编号；然而，这很耗时，并且使演示文稿比需要的要大得多。如果用户从不单击以查看放大的图像，则包含大图像的页面会占用空间。我选择在单击图像时执行vba代码，应该：

>

复制图像

在演示文稿的最后一张幻灯片后创建一张新幻灯片

将图像粘贴到新幻灯片中

法典：

Sub ViewFullSize()

    Dim pptNewSlide As Slide
    ' Dim objCurrentSlideIndex As Integer

    ' objCurrentSlideIndex = ActiveWindow.Selection.SlideRange.SlideIndex

    With ActivePresentation

        .Slides(2).Shapes("Picture 7").Copy

        .Slides(4).Shapes.Paste

    End With


    Set pptNewSlide = ActivePresentation.Slides.Add(ActivePresentation.Slides.Count + 1, ppLayoutCustom)

    ActivePresentation.SlideShowWindow.view.Last

End Sub

这段代码执行并执行所显示的内容。我的问题是，我需要幻灯片编号和形状编号作为变量。我不想为100张可以点击的照片重写这段代码片段。我试图使当前幻灯片成为这样的变量：

    Dim objCurrentSlideIndex As Integer
    objCurrentSlideIndex = ActiveWindow.Selection.SlideRange.SlideIndex
    With ActivePresentation
        .Slides(objCurrentSlideIndex).Shapes("Picture 7").Copy
        .Slides(4).Shapes.Paste`
    End With

我尝试的变量< code >。slides(objCurrentSlideIndex)导致整个子例程不执行，但不会使幻灯片崩溃。我使用了< code>Set和许多其他语法，但无法让它使用变量而不是普通数字。有办法做到这一点吗？可以将<代码>。Slides()和< code >。Shapes()方法甚至使用变量？我读了微软和PPTools的一些页面，但是找不到使用变量的例子。

Answer 1

完整的工作代码！

对于任何感兴趣的人来说，这是我在Powerpoint 2017中完成的(可能不是收集的)完全可操作的代码。

这被设计为作为一个宏动作分配给幻灯片中的图片。当一个页面上有多个较小尺寸的图像时，可以为每个图像分配一个宏，该宏将在其自己的幻灯片上全屏显示图像，然后将用户发送回包含较小图像的屏幕。这有点像全屏缩放功能。

这是我所能记录的最好的文件，允许任何人跟踪每一步发生的事情。如果我说错了什么，欢迎对适当的措辞和术语进行编辑。

这并不特定于我的机器或路径或类似的东西。您可以简单地复制并粘贴到powerpoint中的模块中，然后开始将新宏分配给演示文稿中的任何图像。

Sub ViewFullSize(objCurrentShape As Shape) ' Place shape clicked-on into variable.
 ' Credit Shyam Pillai @ http://www.skphub.com/ppt00040.htm#2 for the method of
 ' bringing the shape into the macro as a variable allowing easier manipulation.

    Dim pptNewSlide As Slide
    Dim objCurrentSlideNum As Integer
    Dim objLastSlideNum As Integer
    Dim objLargeView As Shape

' Place current slide number into a variable.
    objCurrentSlideNum = ActivePresentation.SlideShowWindow.view.CurrentShowPosition

' Copy shape to clipboard for later pasting.
    ActivePresentation.Slides(objCurrentSlideNum).Shapes(objCurrentShape.Name).Copy

' Place new blank slide at the end of the presentation.
    Set pptNewSlide = ActivePresentation.Slides.Add(ActivePresentation.Slides.Count + 1, ppLayoutBlank)

' Make the new slide the active slide.
    ActivePresentation.SlideShowWindow.view.Last

' Place the new slide number into a variable.
    objLastSlideNum = ActivePresentation.SlideShowWindow.view.CurrentShowPosition

' Paste the shape image from the clipboard onto the new slide.
    ActivePresentation.Slides(objLastSlideNum).Shapes.Paste

' Put pasted image into a variable.
    Set objLargeView = ActivePresentation.Slides(objLastSlideNum).Shapes(1)

' Full credit for this next section of the code goes to PPTools & David Marcovitz
' @ http://www.pptfaq.com/FAQ00352_Batch_Insert_a_folder_full_of_pictures-_one_per_slide.htm
' Thanks for the hard work!

' Manipulate the image using the variable.
    With objLargeView
      ' Set mouse-click action on image to return user back to the slide they came from.
        .ActionSettings(ppMouseClick).Action = ppActionLastSlideViewed
      ' Reposition the image for proper resizing
        .Left = 0
        .Top = 0
        .ScaleHeight 1, msoTrue
        .ScaleWidth 1, msoTrue
      ' Resize the image to full screen while maintaining aspect ratio.
      ' This is wide screen mode.  If you are working with the more
      ' narrow mode, simply change the 9 to a 3 and the 16 to a 4
      ' to keep the correct aspect ratio.
        If 9 * .Width > 16 * .Height Then
            .Width = ActivePresentation.PageSetup.SlideWidth
            .Top = 0.5 * (ActivePresentation.PageSetup.SlideHeight - .Height)
        Else
            .Height = ActivePresentation.PageSetup.SlideHeight
            .Left = 0.5 * (ActivePresentation.PageSetup.SlideWidth - .Width)
        End If
    End With
' From here, the slideshow is now showing the originally clicked-on image
' full screen on its own page waiting for the user to click on it to return
' to the rest of the show.  If the slideshow isn't set to kiosk mode, then
' there is the possibility of the user clicking somewhere on the screen out
' of the picture area and it would end the slideshow.
End Sub

Answer 2

Sub ViewFullSize(objCurrentShape As Shape) ' Place shape clicked on into variable.

    Dim pptNewSlide As Slide
    Dim objCurrentSlideNum As Integer
    Dim objLastSlideNum As Integer

' Place current slide number into a variable.
    objCurrentSlideNum = ActivePresentation.SlideShowWindow.view.CurrentShowPosition

' Send shape to clipboard for later pasting.
    ActivePresentation.Slides(objCurrentSlideNum).Shapes(objCurrentShape.Name).Copy

' Place new blank slide at the end of the presentation.
    Set pptNewSlide = ActivePresentation.Slides.Add(ActivePresentation.Slides.Count + 1, ppLayoutCustom)

' Make the new slide the active slide.
    ActivePresentation.SlideShowWindow.view.Last

' Place the new slide number into a variable.
    objLastSlideNum = ActivePresentation.SlideShowWindow.view.CurrentShowPosition

' Paste the shape image from the clipboard onto the new slide.
    ActivePresentation.Slides(objLastSlideNum).Shapes.Paste

End Sub

我偶然发现了一段代码，它显示当单击一个形状时，它可以将其标识符直接传递到子例程中并分配给一个变量。在我的例子中，（对象货币形状为形状）。然后这可以与. Shapes（）方法一起使用，我用它来调用形状以复制. Shapes（objCurrentShape.Name）. Copy。

该 .Slides（）方法更容易分配给变量（或者我相信如此），因为它不依赖于单击哪个形状。它只是活动的幻灯片编号，并且是通过 .查看当前显示位置函数。

此代码现在可以分配给幻灯片上任意数量的形状，并将该形状复制并通过到演示文稿末尾新创建的空白幻灯片以供进一步操作。