继续Jenkins管道通过失败阶段

Question

我有一系列执行快速检查的阶段。我想完成所有这些，即使有失败。例如：

stage('one') {
    node {
        sh 'exit 0'
    }
}
stage('two') {
    node {
        sh 'exit 1'   // failure
    }
}
stage('three') {
    node {
        sh 'exit 0'
    }
}

第二阶段失败，因此默认情况下第三阶段不执行。

通常这将是并行的工作，但我想在阶段视图中显示它们。在下面的模型中：

• 构建4显示了通常发生的情况。作业two失败，因此two不运行

Answer 1

这取决于您使用的是声明性管道语法还是脚本管道语法。

声明性管道语法：

pipeline {
    agent any
    stages {
        stage('one') {
            steps {
                sh 'exit 0'
            }
        }
        stage('two') {
            steps {
                sh 'exit 1'   // failure
            }
        }
    }
    post {
        always {
            sh 'exit 0'
        }
    }
}

Post条件块包含与步骤部分相同的步骤。

脚本化管道语法：

node {

    def build_ok = true

    stage('one') {
        sh 'exit 0'
    }

    try{
        stage('two') {
            sh 'exit 1'   // failure
        }
    } catch(e) {
        build_ok = false
        echo e.toString()  
    }

    stage('three') {
        sh 'exit 0'
    }

    if(build_ok) {
        currentBuild.result = "SUCCESS"
    } else {
        currentBuild.result = "FAILURE"
    }
}

Answer 2

我也有同样的担忧。我能够解决它这样做。

第二阶段将显示为红色，并标记为失败，而其余阶段将继续运行。您可以设置一个标志，在阶段结束时检查标志并通知整个构建的状态。

node {

    def build_ok = true

    stage('one') {
        sh 'exit 0'
    }

    try{
        stage('two') {
            sh 'exit 1'   // failure
        }
    } catch(e) {
        build_ok = false
        echo e.toString()  
    }

    stage('three') {
        sh 'exit 0'
    }

    ....

    if(build_ok) {
        currentBuild.result = "SUCCESS"
    } else {
        currentBuild.result = "FAILURE"
    }
}

Answer 3

这现在是可能的。下面是一个声明性管道的示例，但是catchError也适用于脚本化管道。

pipeline {
    agent any
    stages {
        stage('1') {
            steps {
                sh 'exit 0'
            }
        }
        stage('2') {
            steps {
                catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE') {
                    sh "exit 1"
                }
            }
        }
        stage('3') {
            steps {
                sh 'exit 0'
            }
        }
    }
}

在上面的示例中，所有阶段都将执行，管道将成功，但阶段2将显示为失败：

正如您可能已经猜到的，您可以自由选择buildResult和stageResult，以防它不稳定或其他任何情况。您甚至可以使构建失败并继续执行管道。

只要确保您的Jenkins是最新的，因为这是一个相当新的功能。

编辑：您需要“管道：基本步骤”2.16（2019年5月14日）