根据今天的日期创建文件夹，并使用批处理文件将文件复制到新文件夹中

Question

我有以下代码，它基于今天的日期创建一个文件夹，并将文件从一个文件夹移动到新的文件夹。我有以下代码：

set date="%date:~7,2%%date:~4,2%%date:~10,4%"
set mydir=%date%
cd "C:\Users\rnan\Desktop\Batch Files\Tess\File History\"
mkdir "C:\Users\rnan\Desktop\Batch Files\Tess\File History\%mydir%"
"C:\Program Files (x86)\WinSCP\WinSCP.com" /command ^
"open ftp://rnan:[e-mail]/tess/" ^
"lcd ""C:\Users\rnan\Desktop\Batch Files\Tess\File History\%mydir%""" ^ 
"get *.csv>1D" ^ 
"exit" 

此代码创建一个文件夹，但不将任何文件复制到新创建的文件夹。正在将文件从FTP服务器复制到新文件夹。请建议一些复制这些文件的更改。

谢谢！

Answer 1

您的代码总体上是正确的（除了date变量的误用，正如@jeff所指出的）。

^周围的空白很可能是错误的。

• ^必须是该行的最后一个字符。在LCD和GET行的^后面似乎有空格。
• ^后面的行必须以空格开头。以下行中没有空格。

请参阅WinSCP常见问题：为什么批处理文件中WinSCP命令行上指定的一些脚本命令没有执行/失败？

而且，您不仅不应该为date变量赋值。您甚至不应该使用这种方式来格式化时间戳，作为特定于区域设置的date变量的格式。请参见在批处理作业中创建文件名作为时间戳。所以，你最好用另一种方法。

WinSCP本身支持使用其%timestamp%语法设置日期格式。

以下代码修复了^的问题，并使用WinSCP可靠地设置日期格式：

set TIMESTAMP_FORMAT=yyyy-mm-dd
cd "C:\Program Files (x86)\WinSCP"
for /F "tokens=* USEBACKQ" %%F in (`WinSCP.com /command "echo %%TIMESTAMP#%TIMESTAMP_FORMAT%%%" "exit"`) do set TIMESTAMP=%%F
set mydir=C:\Users\rnan\Desktop\Batch Files\Tess\File History\%TIMESTAMP%
mkdir "%mydir%"
WinSCP.com /command ^
    "open ftp://rnan:[e-mail]/tess/" ^
    "lcd ""%mydir%""" ^
    "get *.csv>1D" ^
    "exit"