灵活序列化的任何想法

Question

我有一些序列化为输出的对象。对象的某些属性需要大量计算，并且需要一些时间才能完成。我正在考虑的是如何指定用户想要获取的属性集，并仅序列化该集合而不是所有属性集。

我已经做了一些研究，很清楚如何仅序列化标记为[Serializable]属性的对象的所需属性，但在我的例子中，标记为[DataContract]的对象仍然存在一些问题。

现在的另一个问题是指定应该序列化的属性集。理想情况下，最好有像XQuery这样的东西来指定应该序列化的确切内容。

所以，就目前而言，问题多于答案...任何想法/想法//建议非常欢迎！

Answer 1

下面的例子创建了一个简单的建筑，每层有3层和4个房间。这不是一个过于复杂的对象图，但我认为它应该传达这个想法。这个想法是你可以实现System.Runtime.Serialization.IS可序列化来控制序列化过程。

在这个例子中，我只实现了System.Runtime.Serialization。Floors类型的ISerializable。在Floors中，类型I控制Rooms列表的序列化和反序列化方式。

如果不了解您的类型的具体细节，特别是计算繁重的属性，我无法具体与他们交谈;但是，我认为通过使用实现System.Runtime.Serialization.ISerializable和控制序列化过程所提供的技术，您将能够实现所需的结果。

请记住，您可以向序列化流中添加任何内容，并且不需要在类中添加所有内容；然而，在反序列化构造函数运行后，您至少需要使类“正确”。您在序列化流中放入的内容取决于您。

但是请注意，这仅适用于二进制序列化，不适用于Xml序列化。

    Module Module1

    Sub Main()
        Dim floor1 As New Floor()
        floor1.Rooms.Add(New Rooms(101))
        floor1.Rooms.Add(New Rooms(102))
        floor1.Rooms.Add(New Rooms(103))
        floor1.Rooms.Add(New Rooms(104))

        Dim floor2 As New Floor()
        floor2.Rooms.Add(New Rooms(201))
        floor2.Rooms.Add(New Rooms(202))
        floor2.Rooms.Add(New Rooms(203))
        floor2.Rooms.Add(New Rooms(204))

        Dim floor3 As New Floor()
        floor3.Rooms.Add(New Rooms(301))
        floor3.Rooms.Add(New Rooms(302))
        floor3.Rooms.Add(New Rooms(303))
        floor3.Rooms.Add(New Rooms(304))

        Dim tower As New Building()
        tower.Floors.Add(floor1)
        tower.Floors.Add(floor2)
        tower.Floors.Add(floor3)

        Dim byteArray As Byte() = Serialized(tower)
        Dim backAgain As Building = DeSerialized(byteArray)
    End Sub

    Private Function Serialized(ByVal tower As Building) As Byte()
        Using ms As New System.IO.MemoryStream()
            Dim formatter As New Runtime.Serialization.Formatters.Binary.BinaryFormatter()
            formatter.Serialize(ms, tower)
            Return ms.GetBuffer()
        End Using
    End Function

    Private Function DeSerialized(ByVal byteArray As Byte()) As Building
        Using ms As New System.IO.MemoryStream(byteArray)
            Dim formatter As New Runtime.Serialization.Formatters.Binary.BinaryFormatter()
            ms.Position = 0
            Return DirectCast(formatter.Deserialize(ms), Building)
        End Using
    End Function
End Module

<Serializable()>
Public Class Building
    Public Sub New()
    End Sub

    Private _Floors As New List(Of Floor)
    Public ReadOnly Property Floors As List(Of Floor)
        Get
            Return _Floors
        End Get
    End Property
End Class

<Serializable()>
Public Class Floor
    Implements System.Runtime.Serialization.ISerializable

    Public Sub New()
    End Sub

    Public Sub New(ByVal info As Runtime.Serialization.SerializationInfo, ByVal context As Runtime.Serialization.StreamingContext)
        Dim counter As Integer = info.GetInt32("RoomCount")
        For index As Integer = 0 To counter - 1
            _Rooms.Add(DirectCast(info.GetValue(String.Format("Room{0}", index.ToString()), GetType(Rooms)), Rooms))
        Next
    End Sub

    Private _Rooms As New List(Of Rooms)
    Public ReadOnly Property Rooms As List(Of Rooms)
        Get
            Return _Rooms
        End Get
    End Property

    Public Sub GetObjectData(info As System.Runtime.Serialization.SerializationInfo, context As System.Runtime.Serialization.StreamingContext) Implements System.Runtime.Serialization.ISerializable.GetObjectData
        info.AddValue("RoomCount", _Rooms.Count)
        For index As Integer = 0 To _Rooms.Count - 1
            info.AddValue(String.Format("Room{0}", index.ToString()), _Rooms(index))
        Next
    End Sub
End Class

<Serializable()>
Public Class Rooms
    Public Sub New()
    End Sub

    Public Sub New(ByVal roomNum As Integer)
        Me.New()
        _RoomNumber = roomNum
    End Sub

    Private _RoomNumber As Integer = 0
    Public Readonly Property RoomNumber As Integer
        Get
            Return _RoomNumber
        End Get
    End Property
End Class