复制文本文件中的最后一段

Question

我有兴趣写一个批处理脚本，它将在一个有许多其他文本块的. txt文件中复制最后一个文本块。想想执行脚本的日志文件，但没有任何一致的内容或长度。每个条目由空行分隔。

因此，对于以下文件，我只想选择并复制最后一段：

知识是一种美德，是一种美德，是一种美德，是一种美德。

但是，在最低限度上，我们需要一个实验室来进行日常工作。

杜伊斯奥特鲁尔杜洛在谴责在波罗的海韦尔特埃塞西莱姆杜洛雷欧盟逃犯nulla pariatur。例外的情况下，不存在，必须在错误的地方，在错误的地方，莫利特和其他地方。

文本本身的长度可以不同。我所需要的唯一可靠指标是，它将是文档中最后一个空行后面的所有内容——在本例中，是“Duis aute…”后面的所有内容

我认为脚本的大纲应该是这样的，但我对batch一点也不熟悉。非常感谢您提供的任何帮助！

SET FOO
FOR /F "delims=" %%G IN (somefile.txt) DO
(IF "%%G"=="" (SET FOO="" )
ELSE (SET FOO==%%G + %FOO%))
ECHO %FOO%>whatever.txt

Answer 1

你可以这样做：

@echo off
setlocal EnableDelayedExpansion
SET "FOO="
type "file.txt" > "file.txt.tmp"
for /f "tokens=1* delims=:" %%A in ('findstr /n "^" "file.txt.tmp"') do if [%%B]==[] (SET "FOO=") else (SET "FOO=!FOO!%%B")
del "file.txt.tmp"
>filepara.txt echo %FOO%

这只有一个缺点，它不会将原始段落中的换行符回显到文本文件中。

编辑：

我找到了一种保持换行符的方法，通过创建一个包含换行符的变量：

@echo off
setlocal EnableDelayedExpansion
set LF=^


SET "FOO="
type "file.txt" > "file.txt.tmp"
for /f "tokens=1* delims=:" eol=¬ %%A in ('findstr /n "^" "file.txt.tmp"') do if [%%B]==[] (SET "FOO=") else (SET "FOO=!FOO!%%B!LF!")
del "file.txt.tmp"
>temp.txt echo !FOO!
more temp.txt > paragraph.txt
del temp.txt

注意：您需要设置LF后的两行空行才能正常工作！

Answer 2

@echo off
setlocal

rem Get the line number of the last empty line
for /F "delims=:" %%a in ('findstr /N "^$" somefile.txt') do set "skip=skip=%%a"

rem Show all lines after it
for /F "%skip% delims=" %%a in (somefile.txt) do echo %%a