使用private（num_threads）子句与default（无子句）的omp节

Question

我使用两个案例执行以下代码：

" $omp节"和"！$omp段私有(thread_num)"

在这两种情况下，每个部分都由不同的线程完成吗？

program main
use omp_lib
implicit none
integer, parameter:: ma=100, n=10000, mb= 100
real, dimension (ma,n) :: a 
real, dimension (n,mb) :: b
real, dimension (ma,mb) :: c = 0. 

integer:: i,j,k, threads=2, ppt, thread_num

integer:: toc, tic, rate 
real:: time_parallel, time 

call random_number (a) 
call random_number (b)

!/////////////////////// PARALLEL PRIVATE ///////////////////////
 c=0
CALL system_clock(count_rate=rate)
call system_clock(tic)

ppt = ma/threads
  !$ call omp_set_num_threads(threads)
  
  !$omp parallel

  !$omp sections private(thread_num)  !(HERE IS THE QUESTION TOPIC)

  ! EXAMPLE PROCESS 1 (it is only an example to test 'omp sections')
  !$omp section  
  !$ thread_num = omp_get_thread_num()
  !$ print*, "Section 1 started by thread number:", thread_num
  do i= 1,50
    do j= 1,mb
      do k= 1,n
        c(i,j) = c(i,j) + a(i,k)*b(k,j)
      end do 
    end do
  end do 
  !$ print*, "Section 1 finished by thread number:", thread_num

  ! EXAMPLE PROCESS 2
  !$omp section  
  !$ thread_num = omp_get_thread_num()
  !$ print*, "Section 2 started by thread number:", thread_num
  do i= 51,100
    do j= 1,mb
      do k= 1,n
        c(i,j) = c(i,j) + a(i,k)*b(k,j)
      end do 
    end do
  end do 
  !$ print*, "Section 2 finished by thread number:", thread_num

!$omp end sections
!$omp end parallel
print*, '//////////////////////////////////////////////////////////////'
print*, 'Result in Parallel' 
!$ print*, c(85:90,40)  
  
call system_clock(toc)
time_parallel = real(toc-tic)/real(rate)

!/////////////////////// normal execution ///////////////////////
 c = 0
CALL system_clock(count_rate=rate)
call system_clock(tic)

  call system_clock(tic)

  do i= 1,ma
    do j= 1,mb
      do k= 1,n
        c(i,j) = c(i,j) + a(i,k)*b(k,j)
      end do 
    end do
  end do 
  
  
call system_clock(toc)
time =  real(toc-tic)/real(rate)
print*, 'Result in serial mode'
print*, c(85:90,40)  
print*, '------------------------------------------------'
print*, 'Threads: ', threads, '|  Time Parallel ', time_parallel, 's '
print*, '                         Time Normal  ', time, 's'
!----------------------------------------------------------------

end program main

这分别是“！$omp sections”和“！$comp sections private（thread_num）”的结果：

第 1 节 按线程数开始：1

第2部分由线程号1开始

第1节按线程编号完成：1

第2节按Thread编号完成：1

//////////////////////////////////////////////////////////////

平行产生

2507.23853 2494.16162 2496.83960 2503.58960 2509.34448
2518.64160

串行模式下的结果

2507.23853 2494.16162 2496.83960 2503.58960 2509.34448
2518.64160

线程:2 |时间平行0.428116574

正常时间0.605000019秒

第1节由线程号0开始

第2部分由线程号1开始

第1部分由线程号0完成

第2节按Thread编号完成：1

//////////////////////////////////////////////////////////////

平行产生

2523.38281 2501.28369 2517.81860 2502.66235 2503.13940
2532.35791

串行模式下的结果

2523.38281 2501.28369 2517.81860 2502.66235 2503.13940
2532.35791

线程：2 |时间并行0.432999998

正常时间0.610204018 s

它是使用以下方法编译的：

Gfortranprog.exeprueba. f90.prog.exe

我笔记本电脑的CPU型号：

AMD A6-6310（4 核，每个核一个线程）

附言：主要目标是测试并行子句，而不是加速矩阵计算

Answer 1

thread_num绝对应该是私有变量。否则两个线程都使用相同的变量，因此您可以从两个线程中获得值1。从两个线程写入同一个变量是一种竞争条件。

您可以将其设置为整个并行区域的私有区域，并且仅在区域开始时调用 omp_get_thread_num（） 一次。

  !$omp parallel private(thread_num)

  !$ thread_num = omp_get_thread_num()

  !$omp sections 
  !$omp section
  !$ print*, "Section 1 started by thread number:", thread_num

  ...