我们如何使用groovy脚本在测试用例中添加SOAP请求测试步骤

Question

我正在寻找在测试用例中添加 SOAP 请求测试步骤，从不同的 TestSuite 和测试用例，我已经对部分进行了编码以添加 Groovy 脚本以满足相同的要求，但无法添加 SOAP 请求测试步骤。有什么帮助吗？

以下是我的代码：

import com.eviware.soapui.impl.wsdl.teststeps.registry.GroovyScriptStepFactory

suite = context.testCase.testSuite.project.addNewTestSuite("AutomatedTestSuite")
tc = suite.addNewTestCase("automatedTestCase")
gs = tc.addTestStep( GroovyScriptStepFactory.GROOVY_TYPE, "GroovyScript1" )
gs2 = tc.addTestStep( GroovyScriptStepFactory.GROOVY_TYPE, "GroovyScript3" )
gs.properties["script"].value = 'log.info(\'hello world\')'

Answer 1

您可以通过项目获得另一个testSuite，testCase和testStep的名称，如下所示：

def project = context.testCase.testSuite.project
def testStep = project.testSuites['TestSuiteName'].testCases['TestCaseName'].testSteps['testStepName']

或者替代使用getXXXXbyName方法的数组方法：

def testStep = project.getTestSuiteByName('TestSuiteName').getTestCaseByName('TestCaseName').getTestStepByName('testStepName')

然后要将此测试步骤添加到您的测试案例中，您可以使用clone步骤（WsdlTest步骤测试步骤，字符串名称）方法。

在您的脚本中：

def suite = context.testCase.testSuite.project.addNewTestSuite("AutomatedTestSuite")
def tc = suite.addNewTestCase("automatedTestCase")

// get desired testStep
def project = context.testCase.testSuite.project
def testStep = project.testSuites['TestSuiteName'].testCases['TestCaseName'].testSteps['testStepName']
// add it to your new generated testCase
tc.cloneStep(testStep,testStep.name + "_Copy")

根据评论进行编辑

如果您想创建一个新的SOAP testStep，而不是另一个SOAP test step的副本，您可以使用下面的代码来完成。考虑到创建SOAP类型的testStep需要比创建groovy类型的test step更多的信息，因为需要wsdl操作信息(在这个例子中，我们使用第一个，但是如果您有多个test step，请注意您所使用的信息)。

在我看来，第一种方法更简单，您可以复制另一个测试步骤并更改您想要的属性...不管怎样，如果你想这样做，你可以:

import com.eviware.soapui.impl.wsdl.teststeps.registry.WsdlTestRequestStepFactory
def suite = context.testCase.testSuite.project.addNewTestSuite("AutomatedTestSuite")
def tc = suite.addNewTestCase("automatedTestCase")

// get the WSDL operation... for the example we take the first one
// however if you've more get the correct one
def operation = testRunner.testCase.testSuite.project.getInterfaceAt(0).getOperationList()[0]
// factory to create the testStepConfig
def factory = new WsdlTestRequestStepFactory()
def config = factory.createConfig(operation,'stepName') 
// create the testStep
def testStep = tc.addTestStep(config)
// change the request
testStep.properties['Request'].value = '<request>someData</request>'

希望对您有所帮助，