如何在spock或hamcrest中创建自定义特定于域的断言/匹配器

Question

我试图在spock或hamcrest中编写一个与域相关的自定义断言/匹配器，但我不确定如何继续。

我曾尝试在hamcrest编写一个自定义匹配器，但到目前为止，这只导致我找到了部分解决方案。

我正在寻找一些指导，关于在这种情况下正确的路线是什么。

域对象：

• ResultMap有一个对象Map

在我的spock测试中，我想做的事情是：

expect:
  that actualResultMap, matchesInAnyOrder(expectedResultMap)
  or
  that actualResultMap, matches(expectedResultMap) // Will only match if everything is in the same order.

然后，内部代码将评估每个条目，并对内部对象进行适当的测试。

到目前为止，我设法编写了一部分代码来评估一组多重映射，但是我不确定如何将我的测试链接起来。

自定义匹配器：

package com.ps.DE.Test.CustomMatcher

import org.hamcrest.BaseMatcher

class MultimapMatcher {

    /**
     * Checks all the entries in a Multimap with another
     * @param expected
     * @return Shows the failure only if the entries do not match or are not in the same order
     */
    static hasAllInOrder(final com.google.common.collect.Multimap expected){
        [
                matches: { actual ->
                    for(key in actual.keySet()){
                        if (actual.get(key) != expected.get(key)){
                            return false
                        }
                    }
                    return true
                },
                describeTo: { description ->
                    description.appendText("MultiMap entries to be ${expected}")
                },
                describeMismatch: { actual, description ->
                    description.appendText("were ${actual}")
                }
        ]   as BaseMatcher
    }

    /**
     * Checks all the entries in a Multimap with another
     * @param expected
     * @return Shows the failure only if the entries do not match
     */
    static hasAllInAnyOrder(final com.google.common.collect.Multimap expected){
        [
                matches: { actual ->
                    for(key in actual.keySet()){
                        if (!actual.get(key).containsAll(expected.get(key))) {
                            return false
                        }
                    }
                    return true
                },
                describeTo: { description ->
                    description.appendText("MultiMap entries to be ${expected}")
                },
                describeMismatch: { actual, description ->
                    description.appendText("were ${actual}")
                }
        ]   as BaseMatcher
    }
}

测试自定义匹配器：

package com.ps.DE.Test.CustomMatcher

import com.google.common.collect.ArrayListMultimap
import com.google.common.collect.Multimap
import spock.lang.Specification

import static com.ps.DE.Test.CustomMatcher.MultimapMatcher.hasAllInAnyOrder
import static com.ps.DE.Test.CustomMatcher.MultimapMatcher.hasAllInOrder
import static org.hamcrest.Matchers.not
import static spock.util.matcher.HamcrestSupport.that


class MultimapMatcherSpec extends Specification {

    def "Test hasAllInOrder"() {
        def actual = ArrayListMultimap.create();

        // Adding some key/value
        actual.put "Fruits", "Apple"
        actual.put "Fruits", "Banana"
        actual.put "Fruits", "Pear"
        actual.put "Vegetables", "Carrot"

        Multimap<String, String> expected = ArrayListMultimap.create();

        // Adding some key/value
        expected.put("Fruits", "Apple");
        expected.put("Fruits", "Banana");
        expected.put("Fruits", "Pear");
        expected.put("Vegetables", "Carrot");

        expect:

        that actual, hasAllInAnyOrder(expected)
        that actual, hasAllInOrder(expected)
    }

    def "Test hasAllInAnyOrder"() {
        Multimap<String, String> actual = ArrayListMultimap.create();

        // Adding some key/value
        actual.put("Fruits", "Apple");
        actual.put("Fruits", "Banana");
        actual.put("Fruits", "Pear");
        actual.put("Vegetables", "Carrot");

        Multimap<String, String> expected = ArrayListMultimap.create();

        // Adding some key/value
        expected.put("Fruits", "Banana");
        expected.put("Fruits", "Apple");
        expected.put("Fruits", "Pear");
        expected.put("Vegetables", "Carrot");

        expect:
        that actual, hasAllInAnyOrder(expected)
        that actual, not(hasAllInOrder(expected))
    }
}

任何帮助或指导都将不胜感激。

Answer 1

你为什么需要定制匹配器？也许，Spock和Groovy足够强大，无需自定义匹配器即可满足您的需求。

要匹配两个Multimap对象以相同顺序具有相同内容，只需执行以下操作：

expected:
actual == expected

在同一个断言中添加更多的代码有什么好处吗？

对于任何顺序的匹配，都有点棘手，但添加排序方法（可以在其他测试类中提取和重用）就足够了。这可能看起来像：

expected:
sortValues(actual) == sortValues(expected)

方法本身：

static Map<String, Collection<String>> sortValues(Multimap<String, String> multimap) {
    multimap.asMap().collectEntries {
        [it.key, it.value.sort(false)]
    }
}

也许为了更好的规范可读性，sortValues（）可能具有名称anyOrder（），这将使断言看起来像：

expect:
anyOrder(actual) == anyOrder(expected)

然后，内部代码将评估每个条目，并对内部对象进行适当的测试。

这一部分可以通过equals方法在每个比较对象类型上实现。