获取Antlr规则的原始文本

Question

我是ANTLR初学者，想计算符号的SHA1-哈希值。

我的简化示例语法：

grammar Example;

method @after{calculateSha1($text); }: 'call' ID;

ID: 'A'..'Z'+;
WS: (' '|'\n'|'\r')+ {skip(); }
COMMENT: '/*' (options {greedy=false;}: .)* '*/' {$channel=HIDDEN}

当词法分析器删除所有空白时，将使用不同的字符串callABC，但是call /* DEF */ ABC不幸的是，获得了相同的SHA1-Hash值。

是否有可能在所有跳过的空格和其他通道的文本之间获得规则的“原始”文本？

（我想到的一种可能性是将所有字符都包含在WS-和COMMENT-lexer规则中，但是还有更多规则，因此这不是很实用。）

我使用标准的ANTLRInputStream来提供Lexer，但是我不知道如何接收原始文本。

Answer 1

而不是skip()-ping WS令牌，也将其放在HIDDEN通道上：

grammar Example;

@parser::members {
  void calculateSha1(String text) {
    try {
      java.security.MessageDigest md = java.security.MessageDigest.getInstance("SHA-1");
      byte[] sha1 = md.digest(text.getBytes());
      System.out.println(text + "\n" + java.util.Arrays.toString(sha1) + "\n");
    } catch(Exception e) {
      e.printStackTrace();
    }
  }
}

parse 
  :  method+ EOF
  ;

method
@after{calculateSha1($text);}
  :  'call' ID
  ;

ID      : 'A'..'Z'+;
WS      : (' ' | '\t' | '\n' | '\r')+ {$channel=HIDDEN;};
COMMENT : '/*' .* '*/' {$channel=HIDDEN;};

上面的语法可以通过以下方式进行测试：

import org.antlr.runtime.*;

public class Main {
  public static void main(String[] args) throws Exception {
    String source = "call ABC call /* DEF */ ABC";
    ExampleLexer lexer = new ExampleLexer(new ANTLRStringStream(source));
    ExampleParser parser = new ExampleParser(new CommonTokenStream(lexer));
    parser.parse();
  }
}

它将以下内容打印到控制台：

致电ABC
[48，-45，113，5，-52，-128，-78，75，-52，-97，-35，25，-55，59，-85，96，-58，58，-96， 10]

致电/ * DEF * / ABC
[-57，-2，-115，-104，77，-37，4，93，116，-123，-47，-4，33，42，-68，-95，-43，91，94， 77]

即：相同的解析器规则，但不同$text的（因此具有不同的SHA1）。