如何以编程方式检查页面的网址是否正在重定向？

Question

我正在尝试提取网页A的内容。使用groovy我尝试了以下操作

......
String urlStr = "url-of-webpage-A"
String pageText = urlStr.toURL().text
//println pageText
.....

上面的代码检索webPage A的文本，只要它不重定向到另一个网页B。如果A重定向到B，则在pageText变量中检索webPage
B的页面内容。有没有一种方法可以编码和检查webPage A是否重定向到其他网页（使用groovy或Java）？

PS：上面的代码不是服务器端逻辑的一部分。我在桌面应用程序范围内的客户端上执行它。

Answer 1

groovy中，您可以通过执行以下操作来实现oachim的建议：

String location = "url-of-webpage-A"
boolean wasRedirected = false
String pageContent = null

while( location ) {
  new URL( location ).openConnection().with { con ->
    // We'll do redirects ourselves
    con.instanceFollowRedirects = false

    // Get the response code, and the location to jump to (in case of a redirect)
    location = con.getHeaderField( "Location" )
    if( !wasRedirected && location ) {
      wasRedirected = true
    }

    // Read the HTML and close the inputstream
    pageContent = con.inputStream.withReader { it.text }
  }
}

println "wasRedirected:$wasRedirected contentLength:${pageContent.length()}"

如果您不想被重定向，并且想要第一页的内容，则只需执行以下操作：

String location = "url-of-webpage-A"
String pageContent = new URL( location ).openConnection().with { con ->
  // We'll do redirects ourselves
  con.instanceFollowRedirects = false

  // Get the location to jump to (in case of a redirect)
  location = con.getHeaderField( "Location" )

  // Read the HTML and close the inputstream
  con.inputStream.withReader { it.text }
}

if( location ) { 
  println "Page wanted to redirect to $location"
}
println "Content was:"
println pageContent