StatusBarWait

等待窗口的状态栏包含指定的字符串。

StatusBarWait [, BarText, Seconds, Part#, WinTitle, WinText, Interval, ExcludeTitle, ExcludeText]

参数

BarText

此命令所等待的文本或部分文本. 默认为空, 这意味着等待目标状态栏变成空的. 此文本是区分大小写的, 且匹配行为由 SetTitleMatchMode 决定, 类似于下面的 WinTitle.

要等待状态栏文本 改变, 请在循环中使用 StatusBarGetText, 或像本页底部的例子那样使用 RegEx.

秒

在超时前等待的秒数 (可以为小数或 表达式), 超时后 ErrorLevel 会被设置为 1. 默认为空, 这意味着无限期等待. 指定 0 等同于指定 0.5.

Part#

要获取的状态栏的那一部分的编号, 可以为 表达式. 默认为 1, 这部分通常包含了我们感兴趣的文本.

WinTitle

窗口标题或识别目标窗口的其他条件。请参阅 WinTitle。

WinText

如果使用此参数, 那么它必须是目标窗口中单个文本元素的子字符串 (和内置的 Window Spy 工具显示的一样). 当 DetectHiddenText 的设置为 ON 时, 那么会检测到隐藏文本元素.

Interval

此命令在等待时对状态栏进行检查的时间间隔 (单位为毫秒), 可以为 表达式. 默认为 50.

ExcludeTitle

标题中含有此参数值的窗口将被排除.

ExcludeText

文本中含有此参数值的窗口将被排除.

ErrorLevel

[v1.1.04+] 如果状态栏无法访问, 则此命令会抛出异常. 想了解更多信息, 请参阅 运行时错误.

如果在状态栏出现匹配文本前命令超时了, 则 ErrorLevel 被设置为 1. 如果状态栏无法访问, 则它被设置为 2. 成功找到匹配时则被设置为 0.

备注

StatusBarWait 尝试读取窗口中首个标准状态栏（类名 msctls_statusbar32）。某些程序使用它们自己的状态栏或微软通用控件的特殊版本。此命令不支持这样的状态栏.

在大多数时候, 与其在循环中使用 StatusBarGetText, 不如使用 StatusBarWait 来的有效率, 因为它包含了避免重复调用 StatusBarGetText 形成的高开销的优化.

StatusBarWait 在开始等待匹配前会确定它的目标窗口. 如果那个目标窗口关闭了, 那么此命令会停止等待, 即使存在另一个匹配指定 WinTitle 和 WinText 的窗口.

当此命令处于等待状态时, 可以通过 热键, 自定义菜单项 或 计时器 启动新的 线程.

窗口标题和文本是区分大小写的. 只有在打开 DetectHiddenWindows 设置时，才能检测到隐藏窗口。

相关

StatusBarGetText, WinGetTitle, WinGetText, ControlGetText

示例

; 下面的例子输入新的搜索模式到现有的资源管理器/搜索窗口.
IfWinExist, Search Results ; 设置上次找到的窗口以简化后面的代码.
{
    WinActivate
    Send, {tab 2}!o*.txt{enter}  ; 在搜索窗口中, 输入要搜索的模式.
    Sleep, 400  ; 给状态栏时间, 等它改变为 "Searching".
    StatusBarWait, found, 30
    if ErrorLevel
        MsgBox, The command timed out or there was a problem.
    else
        MsgBox, The search successfully completed.
}

; 下面的例子等待活动窗口的状态栏 发生变化. 此例子需要 v1.0.46.06+.
SetTitleMatchMode RegEx
IfWinExist A  ; 设置上次找到的窗口为活动窗口 (供下面使用).
{
   StatusBarGetText, OrigText
   StatusBarWait, ^(?!^\Q%OrigText%\E$)  ; 该正则表达式等待文本发生任何变化。
}