ESP8266--Arduino开发（Ticker库软件定时器）

一、前言

Ticker库是ESP8266在ArduinoIDE上自带的软件定时器库，我们可以使用他来实现软件定时器功能。

功能	函数	说明
一次性启动	once_ms(time, timer_cb)	time: 定时时间; timer_cb: 定时器回调函数
	once(time, timer_cb)	单位为s
周期性启动	attach_ms(time, timer_cb, gpioID)	gpioID为传入回调函数的形参
	attach(time, timer_cb, gpioID)	单位为s
停止	detach()
判断定时器是否工作	active()

---

二、周期性定时器的使用

/*
 * Ticker库的基本使用
 * 
 * 每个Ticker需要建立一个回调函数，当定时时间到了后，回调函数将被调用；
 * 理论上可以新建足够多的Ticker对象，但这会受到内存容量的限制
 *
 * 使用Ticker实现LED闪烁，并查询定时器存活状态。
*/

#include <Ticker.h>                       // 使用Ticker库，需要包含头文件

Ticker timer1;                            // 创建一个定时器对象

void setup() {
  Serial.begin(115200);                   // 初始化串口
  
  pinMode(LED_BUILTIN, OUTPUT);           // 设置LED引脚为输出引脚
  digitalWrite(LED_BUILTIN, LOW);         // 设置引脚为低电平，点亮LED

  /* 设置周期性定时0.5s，即500ms，回调函数为timer1_cb，参数为LED引脚号，并启动定时器 */
  timer1.attach(0.5, timer1_cb, LED_BUILTIN);
}

void loop() {
  /* 检测定时器是否为存活状态 */
  if(timer1.active()){
    Serial.println("timer1 is active.");
  }
  else{
    Serial.println("timer1 is not active!");
  }
  delay(100);
}

void timer1_cb(int led_pin) 
{
  int state = digitalRead(led_pin);  // 获取当前led引脚状态
  digitalWrite(led_pin, !state);     // 翻转LED引脚电平
}

三、一次性定时器的使用

/*
 * Ticker库的基本使用
 * 
 * 每个Ticker需要建立一个回调函数，当定时时间到了后，回调函数将被调用；
 * 理论上可以新建足够多的Ticker对象，但这会受到内存容量的限制
 *
 * 使用Ticker实现LED闪烁，并查询定时器存活状态。
*/

#include <Ticker.h>                       // 使用Ticker库，需要包含头文件

Ticker timer1;                            // 创建一个定时器对象
Ticker timer2;                            // 创建定时器用于开启timer1
Ticker timer3;                            // 创建定时器用于关闭timer2

void setup() {
  Serial.begin(9600);                     // 初始化串口
  
  pinMode(LED_BUILTIN, OUTPUT);           // 设置LED引脚为输出引脚
  digitalWrite(LED_BUILTIN, LOW);         // 设置引脚为低电平，点亮LED

  /* 设置timer2和timer分别为1s和3s，用于启动和关闭timer1 */
  timer2.once_ms(1000, timer2_cb);        // 1000ms即1后开启timer1
  timer3.once(3, timer3_cb);              // 3s后关闭timer1
}

void loop() {
  /* 检测定时器是否为存活状态 */
  if(timer1.active()){
    Serial.println("timer1 is active.");
  }
  else{
    Serial.println("timer1 is not active!");
  }
  delay(200);
}

void timer1_cb(int led_pin) 
{
  int state = digitalRead(led_pin);  // 获取当前led引脚状态
  digitalWrite(led_pin, !state);     // 翻转LED引脚电平
}

void timer2_cb()
{
  /* 启动定时器1, 设置周期性定时0.5s，即500ms，回调函数为timer1_cb，参数为LED引脚号 */
  timer1.attach(0.5, timer1_cb, LED_BUILTIN);  
}

void timer3_cb()
{
  /* 关闭定时器1 */
  timer1.detach();  
}