qt creator项目文件的配置解析（部分配置）

• 使用#来注释一行。

• 指定平台相关的配置。可使用win32、unix、android、macx等。用法如下：

  win32:INCLUDEPATH += "C:/mylibs/extra headers"
  unix:INCLUDEPATH += "/home/user/extra headers"
  

  或者

  win32{  # 这里的{不能换到下一行
      Debug:LIBS += -L../../../lib/Debug
      LIBS += Config.lib
  }
  unix{   
   gcc: QMAKE_LFLAGS += -no-pie
  }
  

• 定义常量。如：

  CONFIG(debug, debug|release) {
      APP_OUTPUT_DIR = $$clean_path($$PWD/build/debug)
  } else {
      APP_OUTPUT_DIR = $$clean_path($$PWD/build/release)
  }
  
  APP_PLUGIN_OUTPUT_DIR = $$APP_OUTPUT_DIR/plugins  # 使用APP_OUTPUT_DIR这个常量
  

• 包含其他文件。如：

  include($$(PWD)/deo.pri)   # 将当前目录下的deo.pri文件包含到项目中
  

• TEMPLATE：告诉qmake为这个应用程序生成哪种makefile。其可设置的值如下：

  选项	说明
  app	创建一个用于构建应用程序的Makefile（默认）。
  lib	创建一个用于构建库的Makefile。
  subdirs	创建一个用于构建目标子目录的Makefile，子目录使用SUBDIRS变量指定。
  aux	创建一个不建任何东西的Makefile。如果没有编译器需要被调用来创建目标，比如你的项目使用解释型语言写的，使用此功能。注：此模板类型只能用于Makefile-based生成器。特别是，它不会工作在vcxproj和Xcode生成器。
  vcapp	仅适用于Windows。创建一个Visual Studio应用程序项目。
  vclib	仅适用于Windows。创建一个Visual Studio库项目。

  例如：

  // 项目名称：demo
  // 配置文件：demo.pro
  TEMPLATE = subdirs # 
  
  SUBDIRS += \
      launcher \
      plugins \
      libs
  
  launcher.depends += plugins
  launcher.depends += libs
  plugins.depends += libs
  
  // 子项目名称：launcher
  // 子项目配置文件：launcher.pro # 这个子项目是一个应用
  TEMPLATE = app
  QT += widgets
  
  // 子项目名称：plugins
  // 子项目配置文件：plugins.pro
  TEMPLATE = subdirs
  
  SUBDIRS += \
      xtal_ui_frame \
  
  // 子项目名称：libs
  // 子项目配置文件：libs.pro
  TEMPLATE = subdirs
  
  SUBDIRS += \
      pv_utils \
  

• QT：指定项目中使用Qt的模块。默认情况下，QT包含core和gui，以确保标准的GUI应用程序无需进一步的配置就可以构建。如：

  QT -= gui   # 仅使用core模块
  
  QT += sql network  # 添加sql和network模块
  

• INCLUDEPATH：指定编译项目时应该被搜索的#include目录。如果路径包含空格，需要使用引号包含。如：

  win32:INCLUDEPATH += "C:/mylibs/extra headers"
  unix:INCLUDEPATH += "/home/user/extra headers"
  

• LIBS：指定链接到项目中的库列表。如果是unix，需要使用 -l (library) 和 -L (library path) 标志。在Windows上，如果要qmake正确处理库（也就是说，将库的完整路径传递给链接器），库必须存在。qmake会寻找-l指定的库所在的目录。如果路径包含空格，需要使用引号包含路径。如：

  win32:LIBS += c:/mylibs/math.lib
  unix:LIBS += -L/usr/local/lib -lmath
  

• DEFINES：定义预编译宏。相当于编译参数的-D选项。如：

  DEFINES += USE_MY_STUFF
  

  然后就可以在代码中使用：

  #ifdef USE_MY_STUFF
      // TODO
  #else
      // TODO
  #endif
  

• CONFIG：指定编译器选项和项目配置，值由qmake内部识别并具有特殊意义。其取值（部分）如下：

  取值	说明
  release	项目以release模式构建。如果也指定了debug，那么最后一个生效。
  debug	项目以debug模式构建。
  debug_and_release	项目准备以debug和release两种模式构建。
  ordered	使用subdirs模板时，此选项指定应该按照目录列表的顺序处理它们。
  warn_on	编译器应该输出尽可能多的警告。如果也指定了warn_off，最后一个生效。
  warn_off	编译器应该输出尽可能少的警告。
  exceptions	启用异常支持。默认设置。
  exceptions_off	禁用异常支持。
  rtti	启用RTTI支持。默认情况下，使用编译器默认。
  rtti_off	禁用RTTI支持。默认情况下，使用编译器默认。
  stl	启用STL支持。默认情况下，使用编译器默认。
  stl_off	禁用STL支持。默认情况下，使用编译器默认。
  thread	启用线程支持。
  c++11	启用c++11支持。如果编译器不支持c++11这个选项，没有影响。默认情况下，支持是禁用的。
  c++14	启用c++14支持。如果编译器不支持c++14这个选项，没有影响。默认情况下，支持是禁用的。

  如：

  CONFIG += c++11
  
  win32: CONFIG += console # 在windows平台下，打开cmd窗口
  

• TARGET：生成的应用程序名，即软件名称。

• DESTDIR：指定在何处放置目标文件。

• UI_DIR：指定来自uic的所有中间文件放置的目录（.ui文件转化成ui_*.h文件的存放目录）。

• FORMS：指定UI文件，在编译前被uic处理。所有的构建这些UI文件所需的依赖、头文件和源文件都会自动被添加到项目中。

• MOC_DIR：指定来自moc的所有中间文件放置的目录（含Q_OBJECT宏的头文件转换成标准.h文件的存放目录）。

• OBJECTS_DIR：指定所有中间文件.o（.obj）放置的目录。

• RCC_DIR：指定Qt资源编译器输出文件的目录（.qrc文件转换成qrc_*.h文件的存放目录）。

• RESOURCES：指定资源文件 (qrc)。如：

  RESOURCES += Resource/resource.qrc
  

• RC_FILE：指定应用程序资源文件的名称。这个变量的值通常是由qmake或qmake.conf处理，很少需要进行修改。如：

  RC_FILE += $$PWD/rc/pv.rc
  

• RC_ICONS：仅适用于Windows，指定的图标应该包含在一个生成的.rc文件里。如果RC_FILE 和RES_FILE变量都没有设置这才可利用。如：

  RC_ICONS = myapp.ico
  

• TRANSLATIONS：指定包含用户界面翻译文本的翻译(.ts)文件列表。

• HEADERS：指定项目中所有的头文件。make会自动检测是头文件的类中是否需要moc，并增加适当的依赖关系和文件到项目中，来生成和链接moc文件。

• SOURCES：指定项目中所有源文件。