Excel宏将COUNTA添加到新的顶行

Question

我有一个Excel 2013工作表，其中每列都有一个标题行，然后在部分或所有单元格中使用“DIRECT”一词。列中没有其他数据，只有“直接”或空白。没有列为空，它们都至少有一次“DIRECT”。

我正在寻找一个可以执行以下操作的宏：

• 添加新的顶行

我录制了一个接近的宏，但它有两个问题：

1. 它将COUNTA数据添加到工作簿的最后一行，这是不需要的（填充的列将是几百，而不是几千）
2. 它引用特定的单元格区域，因此可以切断具有更多行的工作表的数据

Sub AddColumnCountsRecorded()
'
' AddColumnCounts Macro
'

'
    Rows("1:1").Select
    Selection.Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
    Range("J1").Select
    ActiveCell.FormulaR1C1 = "=COUNTA(R[2]C:R[15]C)"
    Range("J1").Select
    Selection.Copy
    Range(Selection, Selection.End(xlToRight)).Select
    ActiveSheet.Paste
End Sub

如果有帮助：

>

列“A”可以确定数据可能所在的最后一行（即“用户名”列，因此那里没有空白）-尽管最后一行也会因工作表而异。

第2行（标题行）可以确定数据所在的最后一列—它没有空白列；在每一列中，至少有一个单元格有“DIRECT”一词。

任何关于编辑现有宏或从头开始制作新宏的建议都将不胜感激！

谢啦！

更新：

非常感谢Scott，这是我最终得到的结果-这将非空白单元格计数添加到活动工作表中，并在最后一行停止，其中包含数据。我只是直接调用它，没有下面建议的代码的第二部分：

Sub AddColumnCountsRecorded()

    With ActiveSheet

        .Rows("1:1").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove

        Dim lRow As Long, lCol As Long
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row
        lCol = .Cells(2, .Columns.Count).End(xlToLeft).Column

        .Range(.Cells(1, 2), .Cells(1, lCol)).FormulaR1C1 = "=COUNTA(R[2]C:R[" & lRow & "]C)"

    End With

End Sub

Answer 1

试试这个。我做了一个单独的sub，您也可以传递工作表参考。

Sub AddColumnCountsRecorded(ws As Worksheet)

    With ws

        .Rows("1:1").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove

        Dim lRow As Long, lCol As Long
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row
        lCol = .Cells(2, .Columns.Count).End(xlToLeft).Column

        .Range(.Cells(1, 2), .Cells(1, lCol)).FormulaR1C1 = "=COUNTA(R[2]C:R[" & lRow & "]C)"

    End With

End Sub

这样称呼它：

Sub ColumnCount()

    AddColumnCountsRecorded Worksheets("Sheet1")

End Sub