惯用Clojure将资源从运行的jar复制到外部

Question

这似乎是一个经典问题，但我找不到任何关于它的“clojure方法”。

因此，我在参考资料/（leiningen项目）中有一个foo/目录。当jar'd/uberjar'd时，这个foo/目录放在jar的根目录下。由于jar中的文件在运行时可能在物理上不一致，所以不能使用基本复制函数将目录递归复制到外部世界。

Java世界存在几种解决方案（如何编写一个Java程序，它可以提取JAR文件并将其数据存储在指定的目录（位置）？如何从jar资源中提取目录（和子目录）？例如），但我没有找到任何现有的Clojure解决方案。作为一个初学者（包括Clojure和Java），我不确定如何将上述解决方案翻译成Clojure。从Java逐行翻译成CloJurishJavaInterop似乎不对。有没有一种“官方”的、符合习惯的方法来做到这一点？

请注意，我使用的是Raynes的fs实用程序库。似乎没有一个函数可以直接实现这一点，但也许有一些元素可以用来简化这个过程？（除了明显的基本io糖）

Answer 1

在尝试了更多的方法并得到了#clojure的帮助后，我从我之前的第一个链接中找到了一个“类似于clojure-I-guess”的翻译：

(ns my-ns
  (:require [me.raynes.fs    :as f])
  (:import [java.util.jar JarFile JarEntry]))

(defn extract-dir-from-jar
  "Takes the string path of a jar, a dir name inside that jar and a destination
  dir, and copies the from dir to the to dir."
  [^String jar-dir from to]
  (let [jar (JarFile. jar-dir)]
    (doseq [^JarEntry file (enumeration-seq (.entries jar))]
      (if (.startsWith (.getName file) from)
        (let [f (f/file to (.getName file))]
          (if (.isDirectory file)
            (f/mkdir f)
            (do (f/mkdirs (f/parent f))
                (with-open [is (.getInputStream jar file)
                            os (io/output-stream f)]
                  (io/copy is os)))))))))

我想我可以稍微整理一下（尤其是在.startswithbit周围），但至少它工作得很好。

Answer 2

(defn copy-resource! [resource-filename]
  (let [resource-file (io/resource resource-filename)
        tmp-file (io/file "/tmp" resource-filename)]
    (with-open [in (io/input-stream resource-file)] (io/copy in tmp-file))))

(copy-resource! "my-logo.png")

Answer 3

几个月前我编写了cpath-clj，它将按URI列出类路径上的资源。然后，您可以尝试以下操作：

(require '[cpath-clj.core :as cp]
         '[clojure.java.io :as io])

(doseq [[path uris] (cp/resources (io/resource "foo"))
        :let [uri (first uris)
              relative-path (subs path 1)
              output-file (io/file output-directory relative-path)]]
  (with-open [in (io/input-stream uri)]
    (io/copy in output-file)))

由于编写库时没有考虑到这个用例，因此存在一些杂耍：

• （cp/Resources（io/Resources"foo"））将提供您的foo目录的内容-如果您仅使用（cp/Resources"foo"）类路径上的所有此类目录都会被找到，
• 理论上，类路径上可以有多个具有相同路径的文件，这就是为什么函数返回多个uris；在我们的例子中，只有第一个感兴趣。
• path总是以斜杠开始，所以要得到相对的斜杠，我们必须删除它。

也许这对你有帮助。