awk解决方案，用于按列搜索任何字符的第一个实例（但只有一个！）

Question

我有一个（以前排序的）文本文件，由破折号-或单个字母字符组成。我将非常感谢任何帮助，以更好地理解适当的awk语法，以便在文本文件的每一列中移动，并且如果存在非破折号字符，则仅保留每行中的第一个非破折号字符，或者如果不存在字母字符，则保留该破折号字符...无论哪种情况，结果都是单行文本。文件总是以这样一种方式格式化，即每行具有相同的列数，并且总是首选第一个非破折号字符，无论“较低”行中是否存在其他字母字符。

需要澄清的两个示例：给定此文本文件：

# printf 't---k-\ncha---\n--nn--\n--ab-s\n'

t---k-
cha---
--nn--
--ab-s

程序将从第一列开始，因为第一个字符不是破折号，它将保留一个t。然后我们进入下一列，其中第一行信息是破折号，因此进入第二行，其中选择了h。然后前进到第三列，并移动到第三行以选择n字符等。要报告的预期字符串是：

谢谢。

在第二个例子中，我们有一个非常相似的文本排列，只有一个例外：

#printf 't-----\ncha---\n--nn--\n--ab-s\n'

t-----
cha---
--nn--
--ab-s

请注意，在第二个示例的第四列中没有字母字符。因为不存在这样的字符，我们将在该位置返回破折号。因此，预期产出将是：

than-s

这篇文章强调了一种类似于我试图实现的方法，这篇文章同样提供了一种通过numpy实现的解决方案，但我相信它们都需要适用于整数的函数，而我有一个由字母字符组成的数据集。这篇文章类似地解释了一种使用awk以列方式应用函数的方法，这与我所追求的更接近，正如另一篇awk文章一样。在我看来，我所追求的awk方法同样需要我声明一种列式方法，我认为在函数的开头已经说明了这一点：

awk '{for (i=1;i<=NF;i++){

... 我陷入困境的地方是试图识别函数的下一个参数，我认为我在寻找某种类型的if/else语句。这就是我希望得到进一步澄清的部分。

也许解决方案不需要通过awk来完成——我当然对依赖任何语言的其他策略持开放态度，所以如果Python、Perl或其他策略显然是更合适的语言，谢谢你的教育。

谢谢你的考虑

Answer 1

您可以使用此gnu-awk解决方案：

awk '
BEGIN{FS=""}
{
   for (i=1; i<=NF; ++i)
      a[i]=a[i] $i
}
END {
   s = ""
   for (i=1; i in a; ++i)
      s = s gensub(/^((-)+|-*([^-]).*)$/, "\\2\\3", "1", a[i])
   print s
}' file

Answer 2

在每个Unix设备上的任何shell中使用任何awk：

$ cat tst.awk
{
    numChars = length($0)
    for (i=1; i<=numChars; i++) {
        if ( chars[i] ~ /^-?$/ ) {
            chars[i] = substr($0,i,1)
        }
    }
}
END {
    for (i=1; i<=numChars; i++) {
        printf "%s%s", chars[i], (i<numChars ? "" : ORS)
    }
}

$ awk -f tst.awk file1
thanks

$ awk -f tst.awk file2
than-s