XSLT-复制所有其他节点，添加1个新节点

Question

我已经创建了一个XSLT，我想知道如何在一组标记之间复制所有节点，并在底部添加另一个标记。我创建了XSLT，它具有确定要添加哪个标记以及应该调用什么的所有逻辑。然而，我现在遇到的问题是，我不能复制所有其他标签了。以下是有关文件：

XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/csvImportSchema">
        <csvImportSchema>
            <xsl:for-each select="payload">
                <payload>
                    <xsl:copy-of select="@*"/>
                    <xsl:variable name="ean">
                        <xsl:value-of select="ean"/>
                    </xsl:variable>
                    <xsl:for-each select="../product">
                        <xsl:if test="ean = $ean">
                            <productId><xsl:value-of select="article"/></productId>
                        </xsl:if>
                    </xsl:for-each>
                </payload>
            </xsl:for-each>
        </csvImportSchema>
    </xsl:template>

</xsl:stylesheet>

输入

<?xml version="1.0" encoding="UTF-8"?>
<csvImportSchema>
    <payload>
        <test>1</test>
        <test2>2</test2>
        <test3>3</test3>
        <ean>1111111111</ean>
        <productId/>
    </payload>
    <product>
        <article>722619</article>
        <ean>1111111111</ean>
    </product>
</csvImportSchema>

电流输出

<?xml version="1.0" encoding="utf-8"?>
<csvImportSchema>
    <payload>
        <productId>722619</productId>
    </payload>
</csvImportSchema>

期望的产出

<?xml version="1.0" encoding="UTF-8"?>
<csvImportSchema>
    <payload>
        <test>1</test>
        <test2>2</test2>
        <test3>3</test3>
        <ean>1111111111</ean>
        <productId>722619</productId>
    </payload>
</csvImportSchema>

Answer 1

它应该是简单的改变你的有效负载xsl： cope-of Select="@*"/到

<xsl:copy-of select="*[local-name() != 'productId'] | @*"/>

i、 e.复制所有内容，除了productId，因为您是手动构建的。

这将提供所需的输出

<?xml version="1.0" encoding="utf-8"?>
<csvImportSchema>
  <payload>
    <test>1</test>
    <test2>2</test2>
    <test3>3</test3>
    <ean>1111111111</ean>
    <productId>722619</productId>
  </payload>
</csvImportSchema>

Answer 2

对代码的一个观察。不要使用此选项：

<xsl:variable name="ean">
    <xsl:value-of select="../ean"/>
</xsl:variable>

当你能写下这句话的时候：

<xsl:variable name="ean" select="../ean"/>

它不仅冗长，而且效率极低：不是将$ean绑定到现有节点，而是提取现有节点的字符串值，使用该字符串值形成文本节点，创建新的XML文档树，并将此文本节点添加到此新文档的内容。（我曾经通过消除这个可怕的构造，使样式表的运行速度提高了3倍。）

Answer 3

这个简短而简单的转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="productId">
  <productId>
    <xsl:value-of select="../../product/article"/>
  </productId>
 </xsl:template>
 <xsl:template match="product"/>
</xsl:stylesheet>

应用于提供的XML文档时：

<csvImportSchema>
    <payload>
        <test>1</test>
        <test2>2</test2>
        <test3>3</test3>
        <ean>1111111111</ean>
        <productId/>
    </payload>
    <product>
        <article>722619</article>
        <ean>1111111111</ean>
    </product>
</csvImportSchema>

生成所需的正确结果：

<csvImportSchema>
   <payload>
      <test>1</test>
      <test2>2</test2>
      <test3>3</test3>
      <ean>1111111111</ean>
      <productId>722619</productId>
   </payload>
</csvImportSchema>

说明：

>

标识规则按“原样”复制为其选择执行的每个节点。

匹配产品的重写模板从输出中删除此元素（通过其空主体）。

另一个覆盖模板匹配productId，并使用取自product/article的文本节点子元素生成此元素。