如何使用Gradle6.3将本地罐子包含到胖罐子中？

Question

在运行Java8和Gradle6.3的Linux机器上，我需要构建一个由库混合而成的fat jar，一些库来自Maven Central，其他库来自位于存储库根部的本地libs目录，以及我的build.Gradle和gradlew:

apply plugin: 'java'

repositories {
    mavenCentral()
    flatDir {
        dirs 'libs'
    }
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

task copyLibs(type: Copy) {
    from configurations.compile
    into 'libs'
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    testImplementation "junit:junit:4.12"
}

运行./gradlew clean build和cd build/libs之后，如果我解压缩MyProject.jar可以看到JAR中没有包含任何依赖项。

我的最终目标是使我的项目可执行为java-jar myproject.jar。我该怎么解决这个？

Answer 1

这是一个build.gradle，它生成一个包含本地依赖项的fat jar：

plugins {
    id 'java'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

group 'com.mycompany.foo'
version '1.0'

jar {
    archiveBaseName = 'myjarname'
    archiveVersion = '0.1.0'
    manifest {
        attributes(
                'Main-Class': 'com.mycompany.foo.Main'
        )
    }
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    testImplementation'org.junit.jupiter:junit-jupiter-api:5.7.2'
    testImplementation 'org.assertj:assertj-core:3.20.2'
}