Mov ah，2 and int 1ah-错误的打印时间？

Question

所以，我只是从这个问题中找到了代码。我正在尝试以小时为单位打印当前时间，但输出不是预期的。

这是wroing输出的屏幕截图

预期输出为当前时间：<代码>14 16（秒）

BITS 16
ORG 0x7C00

_start:
    mov ax, 07C0h
    add ax, 288
    mov ss, ax              ; ss = stack space
    mov sp, 4096            ; sp = stack pointer

    mov ax, 07C0h
    mov ds, ax              ; ds = data segment


  call time
  call cvthrs
  call cvtmin
  call cvtsec
  call dsptime

    cli
endloop:
    hlt
    jmp     endloop


time:
;Get time from the system
mov ah,02h
int 1Ah
;ret

;CH - Hours
;CL - Minutes
;DH - Seconds

cvthrs:
;Converts the system time from BCD to ASCII
mov bh,ch ;copy contents of hours (ch) to bh
shr bh, 4
add bh,30h ;add 30h to convert to ascii
mov [tmfld],bh
mov bh,ch
;and bh,0fh
add bh,30h
mov [tmfld + 1],bh
ret

cvtmin:
mov bh,cl ;copy contents of minutes (cl) to bh
shr bh, 4
add bh,30h ;add 30h to convert to ascii
mov [tmfld + 3],bh
mov bh,cl
and bh,0fh
add bh,30h
mov [tmfld + 4],bh
ret

cvtsec:
mov bh,dh ;copy contents of seconds (dh) to bh
shr bh, 4
add bh,30h ;add 30h to convert to ascii
mov [tmfld + 6],bh
mov bh,dh
and bh,0fh
add bh,30h
mov [tmfld + 7],bh
ret

tmfld: db '00:00:00'

dsptime:
;Display the system time
mov ah,13h ;function 13h (Display String)
mov al,0 ;Write mode is zero
mov bh,0 ;Use video page of zero
mov bl,0x0f;Attribute
mov cx,8 ;Character string is 8 long
mov dh,5 ;position on row 5
mov dl,0;and column 0
push ds ;put ds register on stack
pop es ;pop it into es register
lea bp,[tmfld] ;load the offset address of string into BP
int 10H
ret

使用QEMU编译和运行：

nasm time.asm -fbin -o time.img
qemu-system-i386 -drive format=raw,file=./time.img

如何修复此问题？

Answer 1

输出不显示当前时间，因为您给BIOS的远指针位于：BP。WriteString函数13h错误
问题在于ORG 0x7C00指令以及如何设置DS段寄存器。

指定原点7C00h时，指示汇编程序考虑代码的第一个字节驻留在偏移地址7C00h处。这意味着0000h的偏移地址，即段开始的位置和DS应该指向的位置，现在在内存中已经大大降低了。应该在DS中加载的唯一正确值是0。

还可以指定ORG 0000h，然后在DS段寄存器中加载的正确值将是07C0h（就像您所做的那样）。

;ret           in time
;and bh,0fh    in cvthrs

为了获得正确的结果，您需要在time和cvthrs子程序中取消注释这些行。

这是一个快速重写，有一些改进：

BITS 16
ORG 0000h

_start:
    mov ax, 07C0h
    mov ds, ax
    add ax, 32
    mov ss, ax              ; ss = 07E0h
    mov sp, 4096            ; sp = stack pointer

    call time

    mov  al, ch           ; hours
    call cvt              ; -> AX
    mov  [tmfld + 0], ax
    mov  al, cl           ; minutes
    call cvt              ; -> AX
    mov  [tmfld + 3], ax
    mov  al, dh           ; seconds
    call cvt              ; -> AX
    mov  [tmfld + 6], ax

    call dsptime

    cli
endloop:
    hlt
    jmp     endloop


time:           ; Get time from the system
mov ah, 02h
int 1Ah         ; BIOS.ReadRealTimeClock
jnc OK
mov cx, 9999h   ; Displays 99:99:99 if clock is malfunctioning
mov dh, 99h
OK:
ret

;CH - Hours
;CL - Minutes
;DH - Seconds

cvt:
mov  ah, al
shr  al, 4
and  ah, 0Fh
add  ax, 3030h
ret

tmfld: db '00:00:00'

dsptime:
;Display the system time
mov  ah, 13h     ;function 13h (Display String)
mov  al, 0       ;Write mode is zero
mov  bh, 0       ;Use video page of zero
mov  bl, 0Fh     ;Attribute
mov  cx, 8       ;Character string is 8 long
mov  dh, 5       ;position on row 5
mov  dl, 0       ;and column 0
push ds          ;put ds register on stack
pop  es          ;pop it into es register
mov  bp, tmfld   ;load the offset address of string into BP
int  10h
ret

times 510-($-$$) db 0
dw 0AA55h

如果您使用mov指令加载tmfld的地址，则会缩短1个字节。
您可以通过将对相关字节大小寄存器的加载合并为相应字大小寄存器的1个加载来进一步改进这一点：

e、 g.变更：

mov  dh, 5       ;position on row 5
mov  dl, 0       ;and column 0

进入

mov  dx, 0500h   ; DH=5 (row), DL=0 (column)