如何创建Gradle任务以在Spring中只运行特定的测试

Question

我有一个Spring项目，在那里我编写了一些单元和集成测试。现在我要创建用于运行所有单元测试、所有集成测试的自定义任务和用于运行两者的一个任务。但我怎么能这样做呢？

Answer 1

我建议将集成测试分离到单独的源集中。默认情况下，您已经有两个源集，一个用于生产代码，一个用于测试。创建新的源集（在src/integrationtest/java下创建新目录），并使用JUnit5添加以下配置：

test {
  useJUnitPlatform()
}

sourceSets {
  integrationTest {
    java.srcDir file("src/integrationTest/java")
    resources.srcDir file("src/integrationTest/resources")
    compileClasspath += sourceSets.main.output + configurations.testRuntime
    runtimeClasspath += output + compileClasspath
  }
}

对于单独的任务：

task integrationTest(type: Test) {
  description = 'Runs the integration tests.'
  group = 'verification'
  testClassesDirs = sourceSets.integrationTest.output.classesDirs
  classpath = sourceSets.integrationTest.runtimeClasspath

  useJUnitPlatform()

  reports {
    html.enabled true
    junitXml.enabled = true
  }
}

现在您有3个可用任务：

null

task coverageMerge(type: JacocoMerge) {
  destinationFile file("${rootProject.buildDir}/jacoco/test.exec")
  executionData fileTree(project.rootDir.absolutePath).include("**/build/jacoco/*.exec")
}

// aggregate all coverage data at root level
if (tasks.findByName("test")) {
  tasks.findByName("test").finalizedBy coverageMerge
}

if (tasks.findByName("integrationTest")) {
  tasks.findByName("integrationTest").finalizedBy coverageMerge
}

task codeCoverageReport(type: JacocoReport) {
  executionData fileTree(project.rootDir.absolutePath).include("**/build/jacoco/*.exec")
  subprojects.each {
    if (!it.name.contains('generated')) {
      sourceSets it.sourceSets.main
    }
  }
  reports {
    xml.enabled true
    html.enabled true
    html.setDestination(new File("${buildDir}/reports/jacoco"))
    csv.enabled false
  }
}

gradlew codeCoverageReport