将一个字符传递给函数并返回多少个以接受字符开头的员工姓名？

Question

我创建了一个函数来传递一个字符，并返回以接受字符开始的员工姓名计数。问题是，当我使用PLSQL块执行PLSQL函数时，出现“PLS-00201：必须声明标识符‘G’”

我已经使用select语句执行了函数，并且成功显示了输出，但当我尝试使用PLSQL块执行函数时，出现错误：PLS-00201：必须声明标识符“G”

create or replace function charcount(v_char in varchar2)

return varchar2

is

v_character number;

begin 

select count(*) into v_character from employees where substr(First_name,1,1)= v_char;

return v_character;

end;

使用PLSQL块执行PLSQL函数：

declare 

 v_char char;

 v_count number;

begin

 v_char:=&v_char;

 v_count:=charcount(v_char);

 dbms_output.put_line(v_count);

end;

输入替代变量

v_char=G.

output=11.

Answer 1

您需要使用

declare 
    v_char varchar2(1) := '&textinput';
    v_count number;
begin 
    v_count := charcount(v_char);    
    dbms_output.put_line(v_count);
end;

注意，在PL/SQL中，您可以在声明变量时分配一个值，这样可以节省以后的步骤。

我还将char更正为标准Oracle字符串类型varchar2。

为了可读性，我更喜欢在赋值运算符的两侧留一个空格。我发现x:=y通常比x:=y更可读。此外，我认为缩进的行业标准是2或4（我个人不喜欢2），任何小于或大于2的东西都看起来不必要的奇怪。

在你的职能范围内，你可以考虑改变

where substr(first_name,1,1) = v_char;

到

where first_name like v_char||'%';

利用first\u name上的任何索引。（它还允许您传递多个字符的字符串。）

顺便说一句，通常的惯例是为变量使用前缀v（v表示变量，有时为局部变量，有时为l），并为参数（通常为p，有时为in）。

将所有这些结合在一起可以得到：

create or replace function charcount
    ( p_matchstring in varchar2 )
    return varchar2
is
    l_num_matching number;
begin
    select count(*) into l_num_matching
    from   employees
    where  first_name like p_matchstring||'%';

    return l_num_matching;
end charcount;

来自SQL*Plus或其他支持替换变量的客户端的调用：

SQL> declare
  2      v_char varchar2(1) := '&textinput';
  3      v_count number;
  4  begin
  5      v_count := charcount(v_char);
  6      dbms_output.put_line(v_count);
  7  end;
  8  /
Enter value for textinput: A
10

甚至只是

begin
    dbms_output.put_line(charcount('&textinput'));
end;

或者（使用SQL*Plus执行命令-尽管这不是SQL或PL/SQL的一部分）：

exec dbms_output.put_line(charcount('&textinput'))

或SQL标准call语句：

call dbms_output.put_line(charcount('&textinput'));