用Groovy模拟Jenkins管道

Question

我对Jenkins pipeline非常陌生，我正在Groovy中构建一个小型共享库<在这种情况下，我试图提出一些单元测试，然后我必须模拟管道对象。

基本上，我有一个Groovy类，其中包含一个方法，该方法使用凭据执行一些操作：

class MyClass implements Serializable {

  def pipeline

  MyClass(def pipeline) {
    this.pipeline = pipeline
  }

  void my method(String version) {
    pipeline.withCredentials([pipeline.usernamePassword(credentialsId: 'MY_ID', usernameVariable: 'MY_USER', passwordVariable: 'MY_PASSWORD')]) {
        pipeline.sh "./release.sh complete --username ${MY_USER} --password ${MY_PASSWORD} --version '${version}'"
    }
  }
}

因此，当谈到这个方法的单元测试时，我创建了一个PipelineMock Groovy类来（尝试）用凭据和用户名密码模拟。

测试类是这样的（有点简化）：

class MyClassTest {

  @Test
  void callWithWithVersionShouldCallCommad() {
    def pipelineMock = new PipelineMock()
    def myClass = new MyClass(pipelineMock)
    myClass('1.0.1')
    assertTrue(pipelineMock.commandCalled.startsWith('./release.sh complete'))
  }

}

我提出的PipelineMock是：

class PipelineMock {

  String commandCalled

  def sh(String command) {
    commandCalled = command
  }

  def usernamePassword(Map inputs) {
    inputs
  }

  def withCredentials(List args, Closure closure) {
    for (arg in args) {
        closure.setProperty(arg.get('usernameVariable'), 'the_login')
        closure.setProperty(arg.get('passwordVariable'), 'the_password')
    }
    closure()
  }

}

最初我只是调用闭包（）来执行代码，但是我得到了错误groovy.lang.MissingProperty tyException：没有这样的属性：MY_USER类：当执行到达pipeline.sh行时，MyClass。
所以我试图将测试值注入到MY_USER和MY_PASSWORD中，这样它们就可以用for循环来解析。我得到了完全相同的错误，但是这次调用closure.set属性时。我在调试时检查了arg.get（'usernameVariable'）正确地解析为MY_USER。

好吧，我迷路了。我不是一个真正的Groovy专家，所以我可能会错过一些东西。任何关于理解正在发生的事情的帮助都将不胜感激！




Answer 1

匿名用户

正如@mkobit在评论中提到的那样，这看起来确实是使用JenkinsPipelineUnit的理想人选，但出于学术兴趣，问题中的样本实际上可以与委托人相关的微小更改一起工作。原始的MyClass中也有一个拼写错误。我的方法应该是MyClass。调用。这是正在工作的PipelineMock

class PipelineMock {

  String commandCalled

  def sh(String command) {
    commandCalled = command
  }

  def usernamePassword(Map inputs) {
    inputs
  }

  def withCredentials(List args, Closure closure) {
    def delegate = [:]
    for (arg in args) {
        delegate[arg.get('usernameVariable')] = 'the_login'
        delegate[arg.get('passwordVariable')] = 'the_password'
    }
    closure.delegate = delegate
    closure()
  }

}

这是没有输入错误的MyClass：

class MyClass implements Serializable {

  def pipeline

  MyClass(def pipeline) {
    this.pipeline = pipeline
  }

  void call(String version) {
    pipeline.withCredentials([pipeline.usernamePassword(credentialsId: 'MY_ID', usernameVariable: 'MY_USER', passwordVariable: 'MY_PASSWORD')]) {
        pipeline.sh "echo ./release.sh complete --username ${MY_USER} --password ${MY_PASSWORD} --version '${version}'"
    }
  }
}

测试应按原样进行。