问题：

XSLT-结合标识模式更改节点上下文的问题

公西良骏

2023-03-14

我有一个给定的源XML文档，其结构如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<sample>
  <definition>
    <variable>
      <name>object01_ID_138368350261919620</name>
      <value>NUL</value>
    </variable>  
    <variable>
      <name>param01_ID_138368350261919621</name>
      <value>10</value>
    </variable>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
  </definition>
  <override>
    <assignment>
      <name>object01_ID_138368350261919620</name>
      <path>module01/object01</path>
    </assignment>
    <assignment>
      <name>param01_ID_138368350261919621</name>
      <path>module01/object01/param01</path>
    </assignment>
    <assignment>
      <name>param02_ID_138368350261919622</name>
      <path>module01/object01/param02</path>
    </assignment>
  </override>
</sample>

<?xml version="1.0" encoding="UTF-8"?>
<sample>
  <definition>
    <variable>
      <name>param00_ID_138368350261919620</name>
      <value>NUL</value>
    </variable>
    <variable>
      <name>param01_ID_138368350261919621</name>
      <value>10</value>
    </variable>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
    <variable>
      <name>Param03_ID_138368350261919623</name>
      <value>1000</value>
    </variable>
  </definition>
  <override>
    <assignment>
      <name>param00_ID_138368350261919620</name>
      <path>module01/object01</path>
    </assignment>
    <assignment>
      <name>param01_ID_138368350261919621</name>
      <path>module01/object01/param01</path>
    </assignment>
    <assignment>
      <name>param02_ID_138368350261919622</name>
      <path>module01/object01/param02</path>
    </assignment>
    <assignment>
      <name>Param03_ID_138368350261919623</name>
      <xpath>module01/object01/param03</xpath>
    </assignment>
  </override>
</sample>

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:fo="http://www.w3.org/1999/XSL/Format" 
  xmlns:xs="http://www.w3.org/2001/XMLSchema" 
  xmlns:fn="http://www.w3.org/2005/xpath-functions" 
  exclude-result-prefixes="fo xs fn">
  <!--
  global declarations ==========================================================
  -->
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>
  <!-- randomid here is just a fake for sake of simplification -->
  <xsl:variable name="randomid" select="138368350261919623"/>
  <!--
  template - identity ==========================================================
  -->
  <xsl:template match="node()|@*" name="identity">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()[1]"/>
    </xsl:copy>
    <xsl:apply-templates select="following-sibling::node()[1]"/>
  </xsl:template>
  <!--
  template - variable assignment ===============================================
  -->
  <xsl:template name="variable_assignment">
    <xsl:param name="value_node_name"/>
    <xsl:param name="value_node_path"/>
    <xsl:message select="'processing: variable assignment'"/>
    <xsl:message select="concat('applying name: ', $value_node_name)"/>
    <xsl:message select="concat('applying path: ', $value_node_path)"/>
    <xsl:call-template name="identity"/>
    <assignment>
      <name>
        <xsl:value-of select="$value_node_name"/>
      </name>
      <xpath>
        <xsl:value-of select="$value_node_path"/>
      </xpath>
    </assignment>
  </xsl:template>
  <!--
    template - processing param03 =============================================
  -->
  <xsl:template match="/sample/override[not(assignment
              /path[matches(text(), '.*/object01/param03$')])]
              /assignment[path[matches(text(), '.*/object01$')]]">
    <!-- setting params -->
    <xsl:param name="value_node_name_target">
      <xsl:value-of select="concat('Param03_ID', '_', $randomid)"/>
    </xsl:param>
    <xsl:param name="value_node_path_target">
      <xsl:value-of select="concat(./path, '/param03')"/>
    </xsl:param>
    <xsl:param name="value_node_value_target" select="'1000'"/>
    <!-- processing variable assignment -->
    <xsl:call-template name="variable_assignment">
      <xsl:with-param name="value_node_name" select="$value_node_name_target"/>
      <xsl:with-param name="value_node_path" select="$value_node_path_target"/>
    </xsl:call-template>
    <!-- processing variable definition -->
    <xsl:for-each select="/sample/definition/*[position()=last()]">
        <xsl:message select="'processing: variable definition'"/>
      <xsl:message select="concat('Here we are: ', .)"/>
      <xsl:message select="concat('applying name: ', $value_node_name_target)"/>
      <xsl:message select="concat('applying value: ', $value_node_value_target)"/>
      <xsl:call-template name="identity"/>
      <variable>
        <name>
          <xsl:value-of select="$value_node_name_target"/>
        </name>
        <value>
          <xsl:value-of select="$value_node_value_target"/>
        </value>
      </variable>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

<?xml version="1.0" encoding="UTF-8"?>
<sample>
  <definition>
    <variable>
      <name>object01_ID_138368350261919620</name>
      <value>NUL</value>
    </variable>
    <variable>
      <name>param01_ID_138368350261919621</name>
      <value>10</value>
    </variable>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
  </definition>
  <override>
    <assignment>
      <name>object01_ID_138368350261919620</name>
      <path>module01/object01</path>
    </assignment>
    <assignment>
      <name>param01_ID_138368350261919621</name>
      <path>module01/object01/param01</path>
    </assignment>
    <assignment>
      <name>param02_ID_138368350261919622</name>
      <path>module01/object01/param02</path>
    </assignment>
    <assignment>
      <name>Param03_ID_138368350261919623</name>
      <xpath>module01/object01/param03</xpath>
    </assignment>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
    <variable>
      <name>Param03_ID_138368350261919623</name>
      <value>1000</value>
    </variable>
  </override>
</sample>

节点上下文变为不更改。新的元素将在最后一个位置添加到元素中，而不是根据需要添加到元素中。
此外，元素中的最后一个元素将复制到元素中。那不是我想要的。

需要帮助！
如果有人能给我一些建议，我将非常感谢，我将不得不以何种方式调整XSLT，以摆脱上面描述的问题和正确的行为。

多谢。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" exclude-result-prefixes="fo xs fn">
  <!--
  global declarations ==========================================================
  -->
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>
  <!-- baserandom here is just a fake for sake of simplification -->
  <xsl:param name="baserandom" select="138368350261919623"/>
  <!--MOVED PARAMS FROM ORIGINAL TEMPLATE HERE SO THEY CAN BE USED BY MULTIPLE TEMPLATES -->
  <!--xsl:param name="value_node_path"-->
  <!--I LEFT THE PREDICATE BECAUSE IT APPEARS THAT THERE COULD BE MORE THAN ONE override ELEMENT.-->
  <!--xsl:value-of select="concat(/sample/override[not(assignment/path[matches(text(), '.*/object01/param03$')])]
            /assignment[1]/path, '/param03')"/>
  </xsl:param>
  <xsl:param name="value_node_value" select="'1000'"/-->
  <!--
  template - identity ==========================================================
  -->
  <xsl:template match="node()|@*" name="identity">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()[1]"/>
    </xsl:copy>
    <xsl:apply-templates select="following-sibling::node()[1]"/>
  </xsl:template>
  <!--
  template - definition ========================================================
  -->
  <!--REPLACES THE xsl:for-each THAT PROCESSES THE VARIABLE DEFINITION-->
  <xsl:template match="definition/*[last()]">
    <xsl:param name="value_node_name"/>
    <xsl:param name="value_node_value"/>
    <xsl:call-template name="identity"/>
    <xsl:if test="$value_node_name">
      <xsl:message select="'processing: variable definition'"/>
      <xsl:message select="concat('Here we are: ', .)"/>
      <xsl:message select="concat('applying name: ', $value_node_name)"/>
      <xsl:message select="concat('applying value: ', $value_node_value)"/>
      <variable>
        <name>
          <xsl:value-of select="$value_node_name"/>
        </name>
        <value>
          <xsl:value-of select="$value_node_value"/>
        </value>
      </variable>
    </xsl:if>
  </xsl:template>
  <!--
    template - processing param03 =============================================
  -->
  <xsl:template match="/sample/override[not(assignment/path[matches(text(), '.*/object01/param03$')])]
        /assignment[path[matches(text(), '.*/object01$')]]">
    <!-- name -->
    <xsl:param name="value_node_name">
      <xsl:value-of select="concat('param03_ID', '_', $baserandom)"/>
    </xsl:param>
    <!-- path -->
    <xsl:param name="value_node_path">
      <xsl:value-of select="concat(./path, '/param03')"/>
    </xsl:param>
    <!-- value -->
    <xsl:param name="value_node_value" select="'1000'"/>
    <!-- processing definition -->
    <xsl:apply-templates select="/sample/definition/*[last()]">
      <xsl:with-param name="value_node_name" select="$value_node_name"/>
      <xsl:with-param name="value_node_value" select="$value_node_value"/>
    </xsl:apply-templates>
    <!-- processing assignment -->
    <xsl:message select="'processing: variable assignment'"/>
    <xsl:message select="concat('applying name: ', $value_node_name)"/>
    <xsl:message select="concat('applying path: ', $value_node_path)"/>
    <xsl:call-template name="identity"/>
    <assignment>
      <name>
        <xsl:value-of select="$value_node_name"/>
      </name>
      <path>
        <xsl:value-of select="$value_node_path"/>
      </path>
    </assignment>
  </xsl:template>
</xsl:stylesheet>

结果XML（仍然错误）：

<?xml version="1.0" encoding="UTF-8"?>
<sample>
  <definition>
    <variable>
      <name>object01_ID_138368350261919620</name>
      <value>NUL</value>
    </variable>
    <variable>
      <name>param01_ID_138368350261919621</name>
      <value>10</value>
    </variable>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
  </definition>
  <override>
    <variable>
      <name>param02_ID_138368350261919622</name>
      <value>100</value>
    </variable>
    <variable>
      <name>param03_ID_138368350261919623</name>
      <value>1000</value>
    </variable>
    <assignment>
      <name>object01_ID_138368350261919620</name>
      <path>module01/object01</path>
    </assignment>
    <assignment>
      <name>param01_ID_138368350261919621</name>
      <path>module01/object01/param01</path>
    </assignment>
    <assignment>
      <name>param02_ID_138368350261919622</name>
      <path>module01/object01/param02</path>
    </assignment>
    <assignment>
      <name>param03_ID_138368350261919623</name>
      <path>module01/object01/param03</path>
    </assignment>
  </override>
</sample>

共有1个答案

欧阳学真

2023-03-14

您遇到的问题是xsl:for-each没有更改输出上下文。它只是改变迭代上下文。

当您迭代xsl:for-each select=“/sample/definition/*[position()=last()]时，仍然在assignment（模板匹配）的上下文中输出。

您需要从定义的上下文输出新的变量。

修改的XSLT 2.0

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:fo="http://www.w3.org/1999/XSL/Format" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:fn="http://www.w3.org/2005/xpath-functions" 
    exclude-result-prefixes="fo xs fn">

    <!--
  global declarations ==========================================================
  -->
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <!-- randomid here is just a fake for sake of simplification -->
    <xsl:param name="randomid" select="138368350261919623"/>
    <!--MOVED PARAMS FROM ORIGINAL TEMPLATE HERE SO THEY CAN BE USED BY MULTIPLE TEMPLATES -->
    <xsl:param name="value_node_name_target">
        <xsl:value-of select="concat('Param03_ID', '_', $randomid)"/>
    </xsl:param>
    <xsl:param name="value_node_path_target">
        <!--I LEFT THE PREDICATE BECAUSE IT APPEARS THAT THERE COULD BE MORE THAN ONE override ELEMENT.-->
        <xsl:value-of select="concat(/sample/override[not(assignment/path[matches(text(), '.*/object01/param03$')])]
            /assignment[1]/path, '/param03')"/>
    </xsl:param>
    <xsl:param name="value_node_value_target" select="'1000'"/>

    <!--
  template - identity ==========================================================
  -->
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()[1]"/>
        </xsl:copy>
        <xsl:apply-templates select="following-sibling::node()[1]"/>
    </xsl:template>

    <!--
  template - variable assignment ===============================================
  -->
    <!--MOVED CODE FROM THIS TEMPLATE INTO THE assignment TEMPLATE-->

    <!--REPLACES THE xsl:for-each THAT PROCESSES THE VARIABLE DEFINITION-->
    <xsl:template match="definition[../override[not(assignment/path[matches(text(), '.*/object01/param03$')])]
        /assignment[path[matches(text(), '.*/object01$')]]]/*[last()]">
        <xsl:message select="'processing: variable definition'"/>
        <xsl:message select="concat('Here we are: ', .)"/>
        <xsl:message select="concat('applying name: ', $value_node_name_target)"/>
        <xsl:message select="concat('applying value: ', $value_node_value_target)"/>
        <xsl:call-template name="identity"/>
        <variable>
            <name>
                <xsl:value-of select="$value_node_name_target"/>
            </name>
            <value>
                <xsl:value-of select="$value_node_value_target"/>
            </value>
        </variable>
    </xsl:template>

    <!--
    template - processing param03 =============================================
  -->
    <xsl:template match="/sample/override[not(assignment/path[matches(text(), '.*/object01/param03$')])]
        /assignment[path[matches(text(), '.*/object01$')]]">
        <!-- setting params -->
        <!--MOVED TEMPLATE PARAMS TO GLOBAL PARAMS-->
        <!-- processing variable assignment -->
        <!--REPLACED UNNECESSARY xsl:call-template WITH ACTUAL CODE-->
        <xsl:message select="'processing: variable assignment'"/>
        <xsl:message select="concat('applying name: ', $value_node_name_target)"/>
        <xsl:message select="concat('applying path: ', $value_node_path_target)"/>
        <xsl:call-template name="identity"/>
        <assignment>
            <name>
                <xsl:value-of select="$value_node_name_target"/>
            </name>
            <!--CHANGED FROM xpath TO path (APPEARED TO BE A TYPO)-->
            <path>
                <xsl:value-of select="$value_node_path_target"/>
            </path>
        </assignment>       <!-- processing variable definition -->
        <!--THIS IS NOW DONE BY A SEPARATE MATCHING TEMPLATE-->
    </xsl:template>
</xsl:stylesheet>

输出

<sample>
   <definition>
      <variable>
         <name>object01_ID_138368350261919620</name>
         <value>NUL</value>
      </variable>
      <variable>
         <name>param01_ID_138368350261919621</name>
         <value>10</value>
      </variable>
      <variable>
         <name>param02_ID_138368350261919622</name>
         <value>100</value>
      </variable>
      <variable>
         <name>Param03_ID_138368350261919623</name>
         <value>1000</value>
      </variable>
   </definition>
   <override>
      <assignment>
         <name>object01_ID_138368350261919620</name>
         <path>module01/object01</path>
      </assignment>
      <assignment>
         <name>param01_ID_138368350261919621</name>
         <path>module01/object01/param01</path>
      </assignment>
      <assignment>
         <name>param02_ID_138368350261919622</name>
         <path>module01/object01/param02</path>
      </assignment>
      <assignment>
         <name>Param03_ID_138368350261919623</name>
         <path>module01/object01/param03</path>
      </assignment>
   </override>
</sample>

类似资料：

使用XSLT更改XML根节点

我是XSLT新手。我想根据其他子节点的条件更改XML中的根节点。但子节点始终保持不变。例如，我有以下XML：我喜欢将XML更改为：这意味着依赖于<代码> 我不想在每个<代码>
基于另一节点的值的XSLT更改值节点
在节点_模块下的文件中所做的更改

我已经改变了文件夹中存在node_modules一些文件。但是当我使用构建应用程序时，当我将其部署到服务器时，我看到了我在node_modules所做的更改。如何克服这一点？我试过以下三种方法 > 我已经将分叉到GIT中，然后我使用了在我的项目中。我已将导入{BsDaterangepickerDirective}从'ngx bootstrap/datepicker'更改为我现在面临以下异常 ./
为什么更改节点上下文不起作用？

我的源XML文档根据元素内容的模式，在元素中的元素中，我希望添加一个新的元素。元素是前导信息。因此，首先，我必须创建一个新的元素及其和内容。之后，我必须创建一个相应的元素，该元素具有相同的内容和特定的内容。这是我的目标XML文档的示例（添加param03): 我的XSLT文档结果XML文档错误我遇到的问题： > 使用不会按预期更改节点上下文。新的元素将在最后一个位置添加到元素中，而不是按照
XSLT将根节点放入目标模式的字符串元素中

我很难解决我面临的一个问题。我们有一个源XML模式，我们正在使用XSLT将其转换为目标模式。然而，目标模式中的一个元素被设计为保存源XML的原始XML（包括atributes）。我不希望使用CDATA，因为当再次使用数据时，这将导致问题。我正在BizTalk2009中运行此XSLT，因此我将仅限于使用XSLT1.0/XPath 1.0。哦，更复杂的是，源XML中的数据在某些元素中有。源示例：
更改JTree中某个节点的图标？

我有一个JTree，它的节点由DefaultMutableTreeNode驱动。每个节点都可以验证或不验证。首先，所有节点的图标都是相同的，但当我选择它们并按下verify按钮时，我将更改已验证节点的图标。我希望能够在每个节点上单击和写入，这样就不能使用JLabel显示图标。我编写了以下代码，但它返回NULLException。数百万，谢谢。

XSLT-结合标识模式更改节点上下文的问题

共有1个答案

相关问答

相关文章

相关阅读

相关工具

相关文档